Add support for creating HW codecs in VideoProcessor tests.

webrtc/modules/video_coding/BUILD.gn

 # Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../../webrtc.gni")
 
@@ skipping 323 matching lines @@
       ":video_coding_utility",
       "../..:webrtc_common",
       "../../base:rtc_base_approved",
       "../../common_video:common_video",
       "../../system_wrappers:system_wrappers",
       "../../test:test_support",
       "../../test:video_test_support",
     ]
   }
 
-  rtc_source_set("video_coding_modules_tests") {
+  rtc_source_set("video_coding_videoprocessor_integration_test") {
     testonly = true
+
     sources = [
-      "codecs/test/videoprocessor_integrationtest.cc",
       "codecs/test/videoprocessor_integrationtest.h",
-      "codecs/vp8/test/vp8_impl_unittest.cc",
     ]
+
     deps = [
       ":video_codecs_test_framework",
       ":video_coding",
       ":webrtc_h264",
       ":webrtc_vp8",
       ":webrtc_vp9",
       "../..:webrtc_common",
+      "../../media:rtc_media",
+      "../../test:test_support",
+      "../../test:video_test_support",
+    ]
+
+    if (is_android) {
+      sources += [
+        "codecs/test/android_test_initializer.cc",
+        "codecs/test/android_test_initializer.h",
+      ]
+
+      deps += [
+        "../../base:rtc_base_approved",
+        "../../sdk/android:libjingle_peerconnection_jni",
+        "//base",
+      ]
+    }
+
+    if (is_ios) {
+      deps += [
+        "../../media:rtc_media_base",
+        "../../sdk:webrtc_h264_video_toolbox",
+      ]
+    }
+  }
+
+  rtc_source_set("video_coding_modules_tests") {
+    testonly = true
+
+    sources = [
+      "codecs/test/videoprocessor_integrationtest.cc",
+      "codecs/vp8/test/vp8_impl_unittest.cc",
+    ]
+
+    deps = [
+      ":video_coding_videoprocessor_integration_test",
+      ":webrtc_vp8",
       "../../api:video_frame_api",
       "../../base:rtc_base_approved",
       "../../common_video:common_video",
-      "../../media:rtc_media_base",
       "../../test:test_support",
       "../../test:video_test_common",
-      "../../test:video_test_support",
       "../video_capture",
     ]
+
     if (rtc_use_h264) {
       defines = [ "WEBRTC_VIDEOPROCESSOR_H264_TESTS" ]
     }
+
     if (!build_with_chromium && is_clang) {
       # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
       suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+    }
+  }
+
+  plot_videoprocessor_integrationtest_resources = [
+    "//resources/foreman_128x96.yuv",

[brandtr, 2017/02/13 12:40:26]

These need to be uploaded to Gstorage.

+    "//resources/foreman_160x120.yuv",
+    "//resources/foreman_176x144.yuv",

[kjellander_webrtc, 2017/02/13 14:31:07]

We already have //resources/paris_qcif.yuv or do we have to have the same video
for the 176x144 size?

[brandtr, 2017/02/13 16:23:02]

Will reuse existing one.

[kjellander_webrtc, 2017/02/14 11:00:14]

Were you going to reuse paris_qcif.yuv? It seems you now added a
foreman_qcif.yuv instead.

[brandtr, 2017/02/14 14:22:37]

Oops, I must have confused this comment with the next.

We do not want to reuse paris_qcif.yuv here, since when comparing metrics we
would like to have the same source material for all resolutions.

+    "//resources/foreman_320x240.yuv",
+    "//resources/foreman_352x288.yuv",

[kjellander_webrtc, 2017/02/13 14:31:08]

352×288 is the size of cif, so this file should be the same as
//resources/foreman_cif.yuv, which seems redundant I guess we could just add
another copy of that .sha1 file with another filename if you rely on the
specific naming of the files for the test.

[brandtr, 2017/02/13 16:23:02]

Thanks for catching this. The same file should be fine, but I'll check with
asapersson@.

+    "//resources/foreman_cif.yuv",
+  ]
+
+  if (is_ios) {
+    bundle_data("plot_videoprocessor_integrationtest_bundle_data") {
+      testonly = true
+      sources = plot_videoprocessor_integrationtest_resources
+      outputs = [
+        "{{bundle_resources_dir}}/{{source_file_part}}",
+      ]
+    }
+  }
+
+  # This executable is meant for local codec perf testing and should not be run

[kjellander_webrtc, 2017/02/13 14:31:07]

Interesting. Is the perf testing that is performed covered by our existing perf
tests in other places then?

[brandtr, 2017/02/13 16:23:02]

Yes. The idea is that the existing perf tests in
videoprocessor_integrationtest.cc are run in "correctness" mode (EXPECTs turned
on) on the regular bots, whereas the new perf tests in
plot_videoprocessor_integrationtest.cc are run manually in "perf mode" (EXPECTs
turned off). The former are for catching regressions, whereas the latter are for
active experimentation on a device. The former already run on the bots, whereas
the latter shouldn't.

I created this build target because that was the simplest way that I could think
of for building the tests in plot_videoprocessor_integration.test, without
adding them to the bots. It's my understanding that all gtests that are added to
the modules_tests target will run on the bots?

[kjellander_webrtc, 2017/02/14 11:00:14]

Acknowledged. Thanks for explaining.

+  # on the trybots/buildbots, hence the existence of this special build target.
+  rtc_test("plot_videoprocessor_integrationtest") {
+    testonly = true
+
+    sources = [
+      "codecs/test/plot_videoprocessor_integrationtest.cc",
+    ]
+
+    deps = [
+      ":video_coding_videoprocessor_integration_test",
+      "../../test:test_main",
+      "../../test:video_test_common",
+      "../video_capture",
+    ]
+
+    data = plot_videoprocessor_integrationtest_resources
+
+    if (is_android) {
+      deps += [
+        "../../base:rtc_base_approved",
+
+        # TODO(brandtr): Figure out if the java dep below could be moved into
+        # :video_coding_videoprocessor_integration_test, where it belongs.
+        "../../sdk/android:libjingle_peerconnection_java",

[brandtr, 2017/02/13 12:40:26]

When I put this dependency in :video_coding_videoprocessor_integration_test, the
corresponding .java files are not put in the apk, leading to runtime errors.

[kjellander_webrtc, 2017/02/13 14:31:08]

Mirko: You can probably explain this better than me.  Is there a supported way
to do that brandtr@ wishes here?

[mbonadei, 2017/02/13 21:19:10]

Unfortunately I came across a similar problem some weeks ago [1] and it seems
that "deps" are not transitive in some Gn templates (but in this case there
should also be another problem). 

I have also tried to take a look at 'rtc_test' and 'test' templates but they are
not easy to grasp.

I try to explain my theory... I am not 100% sure about everything but hopefully
it will explain some parts of the problem. The target type 'rtc_source_set' is
basically a wrapper around 'source_set' and it works as expected (but in that
case we are dealing with C++ code). When we have to deal with Java code we have
to use templates and their behavior is slightly different (I don't know how they
integrate with native Gn targets behind the curtain). In this case we are adding
a dependency with Java code to an 'rtc_source_set' and I think that this is not
supported, while adding a Java dependency to 'rtc_test' works because 'rtc_test'
is based on 'test' [2] which is a template that deals with Java code [3] by
design.

Henrik: Maybe we can create a bug and try to shed some light on this. I can do
that, not in the next couple of weeks but I can try to understand and write
something. The integration between native targets and templates seems to be
tricky.

[1] -
https://codereview.webrtc.org/2646443002/diff/1/webrtc/examples/BUILD.gn#newc...
[2] -
https://chromium.googlesource.com/external/webrtc/+/master/webrtc/webrtc.gni#232
[3] -
https://cs.chromium.org/chromium/src/testing/test.gni?q=testing/test+package:...

[brandtr, 2017/02/14 08:35:26]

Your theory is compatible with my experience: adding the Java dep to the
'rtc_test' target works, but adding it to a 'rtc_source_set' that is being
depended on does not work.

+        "../../sdk/android:libjingle_peerconnection_jni",
+        "//base",
+        "//testing/android/native_test:native_test_support",
+      ]
+
+      shard_timeout = 900
+    }
+
+    if (is_ios) {
+      deps += [ ":plot_videoprocessor_integrationtest_bundle_data" ]
+    }
+
+    if (!build_with_chromium && is_clang) {
+      # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+      suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
     }
   }
 
   rtc_source_set("video_coding_unittests") {
     testonly = true
     sources = [
       "codecs/test/packet_manipulator_unittest.cc",
       "codecs/test/stats_unittest.cc",
       "codecs/test/videoprocessor_unittest.cc",
       "codecs/vp8/default_temporal_layers_unittest.cc",
@@ skipping 70 matching lines @@
     }
 
     # TODO(jschuh): bugs.webrtc.org/1348: fix this warning.
     configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
     if (!build_with_chromium && is_clang) {
       # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
       suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
     }
   }
 }