Decoupling rtc_base from Obj-C code

webrtc/rtc_base/BUILD.gn

 # Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("//build/config/crypto.gni")
 import("//build/config/ui.gni")
@@ skipping 380 matching lines @@
     ]
   } else {
     include_dirs = [ "$rtc_jsoncpp_root" ]
 
     # When defined changes the include path for json.h to where it is
     # expected to be when building json outside of the standalone build.
     defines += [ "WEBRTC_EXTERNAL_JSON" ]
   }
 }
 
 rtc_static_library("rtc_base") {

[kwiberg-webrtc, 2017/08/31 20:46:14]

If you made this a source set, would the need for no-op file go away?

[mbonadei, 2017/09/01 09:24:35]

In the next patch set I have switched to rtc_source_set. Please note that
there are some differences (especially regarding how the linker works on
them):

source_set:
https://chromium.googlesource.com/chromium/src/tools/gn/+/HEAD/docs/reference...
static_library:
https://chromium.googlesource.com/chromium/src/tools/gn/+/HEAD/docs/reference...

If you confirm that a source_set is a good to have I am happy to avoid noop
files (and I will review other CLs too).

[kwiberg-webrtc, 2017/09/01 11:23:44]

The default Chromium advice is to use a source set unless you know you need a
static library. And in this case in particular, almost all the "weight" of this
target is in rtc_base_generic, which is already a static library, so I think a
source set is a good fit.

+  if (is_ios || is_mac) {
+    # In order to build a static_library targeting macOS or iOS
+    # we have to provide at least one source file to avoid a build
+    # error.
+    sources = [
+      "noop.mm",
+    ]
+    public_deps = [
+      ":rtc_base_objc",
+    ]
+  } else {
+    # In order to build a static_library targeting macOS or iOS
+    # we have to provide at least one source file to avoid a build
+    # error.
+    sources = [
+      "noop.cc",
+    ]

[kwiberg-webrtc, 2017/08/31 20:46:14]

I'm confused. In the else clause, we *aren't* on macOS or iOS, so why add a
no-op source file? And why have different types of no-op files for the two
cases?

[mbonadei, 2017/09/01 09:24:35]

Oh wait... Yes you are right! In similar CLs I avoided to add the noop file if
we are
not targeting iOS or macOS. This is probably a leftover that I copy/pasted and 
refactored to look symmetric. :/

Good catch! Thanks!

In the next patch set I switched rtc_base from rtc_static_library to
rtc_source_set
so probably we can drop both noop.{mm,cc}.

+    public_deps = [
+      ":rtc_base_generic",
+    ]

[kwiberg-webrtc, 2017/08/31 20:46:14]

This one could be lifted out of the if-else, right? (And if you did, could
rtc_base_objc have a regular dep instead of a public dep on rtc_base_generic?)

[mbonadei, 2017/09/01 09:24:36]

This is the right thing to do. I was too focused on breaking the circular
dependency
that I overlooked this. It is included in the next patch set. Thanks!

+  }
+}
+
+if (is_ios || is_mac) {
+  rtc_static_library("rtc_base_objc") {
+    sources = [
+      "applefilesystem.mm",
+      "thread_darwin.mm",
+    ]
+    public_deps = [
+      ":rtc_base_generic",
+    ]
+    visibility = [ ":rtc_base" ]
+  }
+}
+
+rtc_static_library("rtc_base_generic") {
   cflags = []
   cflags_cc = []
   libs = []
   defines = []
   deps = [
     "..:webrtc_common",
   ]
   public_deps = [
     ":rtc_base_approved",
   ]
   public_configs = []
 
   all_dependent_configs = [ ":rtc_base_all_dependent_config" ]
 
   sources = [
-    "applefilesystem.mm",
     "asyncinvoker-inl.h",
     "asyncinvoker.cc",
     "asyncinvoker.h",
     "asyncpacketsocket.cc",
     "asyncpacketsocket.h",
     "asyncresolverinterface.cc",
     "asyncresolverinterface.h",
     "asyncsocket.cc",
     "asyncsocket.h",
     "asynctcpsocket.cc",
@@ skipping 73 matching lines @@
     "sslidentity.cc",
     "sslidentity.h",
     "sslstreamadapter.cc",
     "sslstreamadapter.h",
     "stream.cc",
     "stream.h",
     "thread.cc",
     "thread.h",
   ]
 
+  visibility = [
+    ":rtc_base",
+    ":rtc_base_objc",
+  ]
+
   # TODO(henrike): issue 3307, make rtc_base build with the Chromium default
   # compiler settings.
   suppressed_configs += [ "//build/config/compiler:chromium_code" ]
   configs += [ "//build/config/compiler:no_chromium_code" ]
   if (!is_win) {
     cflags += [ "-Wno-uninitialized" ]
   }
 
   if (build_with_chromium) {
     if (is_win) {
@@ skipping 39 matching lines @@
       "ifaddrs-android.h",
     ]
 
     libs += [
       "log",
       "GLESv2",
     ]
   }
 
   if (is_ios || is_mac) {
-    sources += [
-      "macifaddrs_converter.cc",
-      "thread_darwin.mm",
-    ]
+    sources += [ "macifaddrs_converter.cc" ]
   }
 
   if (use_x11) {
     libs += [
       "dl",
       "rt",
       "Xext",
       "X11",
       "Xcomposite",
       "Xrender",
@@ skipping 447 matching lines @@
 if (is_android) {
   android_library("base_java") {
     java_files = [
       "java/src/org/webrtc/ContextUtils.java",
       "java/src/org/webrtc/Logging.java",
       "java/src/org/webrtc/Size.java",
       "java/src/org/webrtc/ThreadUtils.java",
     ]
   }
 }