Decoupling audio_device from Obj-C code

webrtc/modules/audio_device/BUILD.gn

 # Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../../webrtc.gni")
 
@@ skipping 27 matching lines @@
       "-Wno-tautological-compare",
 
       # See https://bugs.chromium.org/p/webrtc/issues/detail?id=6265
       # for -Wno-thread-safety-analysis
       "-Wno-thread-safety-analysis",
       "-Wno-unused-private-field",
     ]
   }
 }
 
+if (rtc_include_internal_audio_device && (is_ios || is_mac)) {
+  rtc_static_library("objc_audio_device") {

[kjellander_webrtc, 2017/08/14 06:54:13]

I prefer audio_device_objc

[mbonadei, 2017/08/16 09:15:25]

Done.

+    sources = [
+      "ios/audio_device_ios.h",
+      "ios/audio_device_ios.mm",
+      "ios/audio_device_not_implemented_ios.mm",
+      "ios/audio_session_observer.h",
+      "ios/objc/RTCAudioSessionDelegateAdapter.h",
+      "ios/objc/RTCAudioSessionDelegateAdapter.mm",
+      "ios/voice_processing_audio_unit.h",
+      "ios/voice_processing_audio_unit.mm",
+    ]
+    libs = [
+      "AudioToolbox.framework",
+      "AVFoundation.framework",
+      "Foundation.framework",
+      "UIKit.framework",
+    ]
+    check_includes = false

[kjellander_webrtc, 2017/08/14 06:54:14]

we usually have this earlier in the target. I'm not sure if the style guide has
any preference, but let's be consistent across our codebase.

[mbonadei, 2017/08/16 09:15:25]

Right. This has been removed in ps#6 because the circular dependency has been
broken.

+    deps = [
+      # There is a cyclic dependency with :audio_device

[kjellander_webrtc, 2017/08/14 06:54:13]

I prefer to have this comment at the check_includes attribute and omit the
commented dependency below. Ideally a bug reference as well that addresses
getting it fixed.

[mbonadei, 2017/08/16 09:15:25]

Done.

+      # ":audio_device",
+      "../../rtc_base:gtest_prod",
+      "../../rtc_base:rtc_base",
+      "../../sdk:objc_audio",
+      "../../sdk:objc_common",
+      "../../system_wrappers:metrics_api",
+    ]
+    if (!build_with_chromium && is_clang) {
+      # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+      suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+    }
+  }
+}
+
 rtc_static_library("audio_device") {
   public_configs = [ ":audio_device_config" ]
 
   deps = [
     "..:module_api",
     "../..:webrtc_common",
     "../../common_audio",
     "../../rtc_base:rtc_base_approved",
     "../../rtc_base:rtc_task_queue",
     "../../system_wrappers",
@@ skipping 110 matching lines @@
           # Needed for CoreGraphics:
           "ApplicationServices.framework",
 
           "AudioToolbox.framework",
           "CoreAudio.framework",
 
           # Needed for CGEventSourceKeyState in audio_device_mac.cc:
           "CoreGraphics.framework",
         ]
       }
       if (is_ios) {

[kjellander_webrtc, 2017/08/16 09:31:53]

I think this would have caused an error if
rtc_include_internal_audio_device=false, which it is for Chromium builds. I
guess it haven't caused any trouble since the audio device code is not built as
part of the Chromium iOS build. Either way, we should fix the problem now as we
move things around.

[kjellander_webrtc, 2017/08/16 09:33:09]

To be clear: you are fixing this in your CL, so this comment is kind of
confusing :)

-        public_deps = [
-          "../../rtc_base:gtest_prod",
-          "../../rtc_base:rtc_base",
-          "../../sdk:objc_audio",
-          "../../sdk:objc_common",
-        ]
-        sources += [
-          "ios/audio_device_ios.h",
-          "ios/audio_device_ios.mm",
-          "ios/audio_device_not_implemented_ios.mm",
-          "ios/audio_session_observer.h",
-          "ios/objc/RTCAudioSessionDelegateAdapter.h",
-          "ios/objc/RTCAudioSessionDelegateAdapter.mm",
-          "ios/voice_processing_audio_unit.h",
-          "ios/voice_processing_audio_unit.mm",
-        ]
-        libs = [
-          "AudioToolbox.framework",
-          "AVFoundation.framework",
-          "Foundation.framework",
-          "UIKit.framework",
-        ]
+        deps += [ ":objc_audio_device" ]
       }
       if (is_win) {
         sources += [
           "win/audio_device_core_win.cc",
           "win/audio_device_core_win.h",
         ]
         libs = [
           # Required for the built-in WASAPI AEC.
           "dmoguids.lib",
           "wmcodecdspuuid.lib",
@@ skipping 48 matching lines @@
     "include/mock_audio_transport.h",
   ]
   deps = [
     ":audio_device",
     "../../test:test_support",
   ]
   all_dependent_configs = [ ":mock_audio_device_config" ]
 }
 
 if (rtc_include_tests) {
+  # TODO(kthelgason): Reenable these tests on simulator.
+  # See bugs.webrtc.org/7812
+  if (is_ios && !use_ios_simulator) {
+    rtc_source_set("objc_audio_device_unittests") {

[kjellander_webrtc, 2017/08/14 06:54:13]

audio_device_objc_unittests

[mbonadei, 2017/08/16 09:15:25]

Done.

+      testonly = true
+      sources = [
+        "ios/audio_device_unittest_ios.mm",
+      ]
+      deps = [
+        ":audio_device",
+        ":mock_audio_device",
+        ":objc_audio_device",
+        "../../rtc_base:rtc_base_approved",
+        "../../sdk:objc_audio",
+        "../../system_wrappers",
+        "../../test:test_support",
+        "//testing/gmock",
+        "//third_party/ocmock",
+      ]
+      if (!build_with_chromium && is_clang) {
+        # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+        suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+      }
+    }
+  }
+
   rtc_source_set("audio_device_unittests") {
     testonly = true
 
     # Skip restricting visibility on mobile platforms since the tests on those
     # gets additional generated targets which would require many lines here to
     # cover (which would be confusing to read and hard to maintain).
     if (!is_android && !is_ios) {
       visibility = [ "..:modules_unittests" ]
     }
     sources = [
       "fine_audio_buffer_unittest.cc",
     ]
     deps = [
       ":audio_device",
       ":mock_audio_device",
       "../../rtc_base:rtc_base_approved",
-      "../../system_wrappers:system_wrappers",
+      "../../system_wrappers",
       "../../test:test_support",
       "../utility:utility",
       "//testing/gmock",
     ]
     if (is_linux || is_mac || is_win) {
       sources += [ "audio_device_unittest.cc" ]
     }
     if (is_android) {
       # Need to disable error due to the line in
       # base/android/jni_android.h triggering it:
       # const BASE_EXPORT jobject GetApplicationContext()
       # error: type qualifiers ignored on function return type
       cflags = [ "-Wno-ignored-qualifiers" ]
       sources += [
         "android/audio_device_unittest.cc",
         "android/audio_manager_unittest.cc",
         "android/ensure_initialized.cc",
         "android/ensure_initialized.h",
       ]
       deps += [
         "../../../base",
         "../../sdk/android:libjingle_peerconnection_java",
       ]
     }
-    if (is_ios && !use_ios_simulator) {
-      # TODO(kthelgason): Reenable these tests on simulator.
-      # See bugs.webrtc.org/7812
-      sources += [ "ios/audio_device_unittest_ios.mm" ]
-      deps += [ "//third_party/ocmock" ]
-    }
     if (!build_with_chromium && is_clang) {
       # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
       suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
     }
   }
 
   if (!is_ios) {
     # These tests do not work on ios, see
     # https://bugs.chromium.org/p/webrtc/issues/detail?id=4755
     rtc_executable("audio_device_tests") {
@@ skipping 26 matching lines @@
       "android/java/src/org/webrtc/voiceengine/WebRtcAudioManager.java",
       "android/java/src/org/webrtc/voiceengine/WebRtcAudioRecord.java",
       "android/java/src/org/webrtc/voiceengine/WebRtcAudioTrack.java",
       "android/java/src/org/webrtc/voiceengine/WebRtcAudioUtils.java",
     ]
     deps = [
       "../../rtc_base:base_java",
     ]
   }
 }