Decoupling rtc_base_approved from Obj-C code

webrtc/rtc_base/BUILD.gn

 # Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("//build/config/crypto.gni")
 import("//build/config/ui.gni")
@@ skipping 13 matching lines @@
     ":rtc_base_approved",
     ":rtc_task_queue",
     ":sequenced_task_checker",
     ":weak_ptr",
   ]
   if (is_android) {
     public_deps += [ ":base_java" ]
   }
 }
 
-config("rtc_base_approved_all_dependent_config") {
-  if (is_mac && !build_with_chromium) {
-    libs = [ "Foundation.framework" ]  # needed for logging_mac.mm
-  }
-}
-
 config("rtc_base_chromium_config") {
   defines = [ "NO_MAIN_THREAD_WRAPPING" ]
 }
 
 config("rtc_base_all_dependent_config") {
   if (is_ios) {
     libs = [
       "CFNetwork.framework",
       "Security.framework",
       "SystemConfiguration.framework",
@@ skipping 29 matching lines @@
     ]
   }
 }
 
 source_set("compile_assert_c") {
   sources = [
     "compile_assert_c.h",
   ]
 }
 
+rtc_source_set("rtc_base_approved") {
+  public_deps = [
+    ":rtc_base_approved_generic",
+  ]
+  if (is_mac && !build_with_chromium) {
+    public_deps += [ ":rtc_base_approved_objc" ]
+  }
+}
+
 # The subset of rtc_base approved for use outside of libjingle.
-rtc_static_library("rtc_base_approved") {
+rtc_source_set("rtc_base_approved_generic") {
   # TODO(kjellander): Remove (bugs.webrtc.org/7480)
   # Enabling GN check triggers a cyclic dependency caused by rate_limiter.cc:
   #   :rtc_base_approved -> ../system_wrappers -> :rtc_base_approved

[kwiberg-webrtc, 2017/09/01 12:31:05]

This comment is supposed to apply to check_includes below.

+  visibility = [
+    ":rtc_base_approved",
+    ":rtc_base_approved_objc",
+  ]
   check_includes = false
   defines = []
   libs = []
   deps = []
-  all_dependent_configs = [ ":rtc_base_approved_all_dependent_config" ]
 
   sources = [
     "array_view.h",
     "arraysize.h",
     "atomicops.h",
     "base64.cc",
     "base64.h",
     "basictypes.h",
     "bind.h",
     "bitbuffer.cc",
@@ skipping 95 matching lines @@
     # Dependency on chromium's logging (in //base).
     deps += [ "//base:base" ]
     sources += [
       "../../webrtc_overrides/webrtc/rtc_base/logging.cc",
       "../../webrtc_overrides/webrtc/rtc_base/logging.h",
     ]
   } else {
     sources += [
       "logging.cc",
       "logging.h",
-      "logging_mac.mm",
     ]
   }
   if (is_component_build && is_win) {
     # Copy the VS runtime DLLs into the isolate so that they don't have to be
     # preinstalled on the target machine. The debug runtimes have a "d" at
     # the end.
     # This is a copy of https://codereview.chromium.org/1783973002.
     # TODO(ehmaldonado): We'd like Chromium to make this changes easier to use,
     # so we don't have to copy their changes and risk breakages.
     # See http://crbug.com/653569
@@ skipping 59 matching lines @@
       } else {
         data += [ "$clang_base_path/lib/clang/$clang_version/lib/windows/clang_rt.asan_dynamic-i386.dll" ]
       }
     }
   }
   if (is_nacl) {
     deps += [ "//native_client_sdk/src/libraries/nacl_io" ]
   }
 }
 
+if (is_mac && !build_with_chromium) {
+  config("rtc_base_approved_objc_all_dependent_config") {
+    visibility = [ ":rtc_base_approved_objc" ]
+    libs = [ "Foundation.framework" ]  # needed for logging_mac.mm
+  }
+
+  rtc_source_set("rtc_base_approved_objc") {
+    visibility = [ ":rtc_base_approved" ]
+    all_dependent_configs = [ ":rtc_base_approved_objc_all_dependent_config" ]
+    sources = [
+      "logging_mac.mm",
+    ]
+    deps = [
+      ":rtc_base_approved_generic",
+    ]
+  }
+}
+
 config("enable_libevent_config") {
   defines = [ "WEBRTC_BUILD_LIBEVENT" ]
 }
 
 rtc_source_set("rtc_task_queue") {
   deps = [
     ":rtc_base_approved",
   ]
   public_deps = [
     ":rtc_task_queue_api",
@@ skipping 770 matching lines @@
       "java/src/org/webrtc/ContextUtils.java",
       "java/src/org/webrtc/Logging.java",
       "java/src/org/webrtc/Size.java",
       "java/src/org/webrtc/ThreadUtils.java",
     ]
 
     # TODO(sakal): Fix build hooks crbug.com/webrtc/8148
     no_build_hooks = true
   }
 }