Support building WebRTC without audio and video for IOS

webrtc/sdk/objc/Framework/Classes/PeerConnection/RTCPeerConnectionFactory.mm

 /*
  *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
  *
  *  Use of this source code is governed by a BSD-style license
  *  that can be found in the LICENSE file in the root of the source
  *  tree. An additional intellectual property rights grant can be found
  *  in the file PATENTS.  All contributing project authors may
  *  be found in the AUTHORS file in the root of the source tree.
  */
 
 #import "RTCPeerConnectionFactory+Private.h"
 
 #import "NSString+StdString.h"
 #import "RTCAudioSource+Private.h"
 #import "RTCAudioTrack+Private.h"
 #import "RTCMediaConstraints+Private.h"
 #import "RTCMediaStream+Private.h"
 #import "RTCPeerConnection+Private.h"
 #import "RTCVideoSource+Private.h"
 #import "RTCVideoTrack+Private.h"
 #import "RTCAVFoundationVideoSource+Private.h"
 #import "WebRTC/RTCLogging.h"
 
 #include "Video/objcvideotracksource.h"
 #include "VideoToolbox/videocodecfactory.h"
 #include "webrtc/api/videosourceproxy.h"
+// Adding the nogncheck to disable the including header check.
+// The no-media version PeerConnectionFactory doesn't depend on media related C++ target.

[tommi, 2017/06/28 15:06:45]

please run |git cl format|

[Zhi Huang, 2017/06/28 19:47:10]

This is what I got after git cl format. It seems that the style guide are
different for objc file. The column limitation is 100.
But I can manually make it 80 since this is c++ code.

+// TODO(zhihuang): Remove nogncheck once MediaEngineInterface is moved to C++ API layer.
+#include "webrtc/media/engine/webrtcmediaengine.h"  // nogncheck
 
 @implementation RTCPeerConnectionFactory {
   std::unique_ptr<rtc::Thread> _networkThread;
   std::unique_ptr<rtc::Thread> _workerThread;
   std::unique_ptr<rtc::Thread> _signalingThread;
   BOOL _hasStartedAecDump;
 }
 
 @synthesize nativeFactory = _nativeFactory;
 
 - (instancetype)init {
   if ((self = [super init])) {
     _networkThread = rtc::Thread::CreateWithSocketServer();
     BOOL result = _networkThread->Start();
     NSAssert(result, @"Failed to start network thread.");
 
     _workerThread = rtc::Thread::Create();
     result = _workerThread->Start();
     NSAssert(result, @"Failed to start worker thread.");
 
     _signalingThread = rtc::Thread::Create();
     result = _signalingThread->Start();
     NSAssert(result, @"Failed to start signaling thread.");
-
+#ifdef HAVE_NO_MEDIA
+    _nativeFactory = webrtc::CreateModularPeerConnectionFactory(
+        _networkThread.get(),
+        _workerThread.get(),
+        _signalingThread.get(),
+        nullptr /*default_adm*/,

[tommi, 2017/06/28 15:06:45]

can we use // comment style?

nullptr,  // default_adm
(etc)

[Zhi Huang, 2017/06/28 19:47:10]

Yeah, sure. Done.

+        nullptr /*audio_encoder_factory*/,
+        nullptr /*audio_decoder_factory*/,
+        nullptr /*video_encoder_factory*/,
+        nullptr /*video_decoder_factory*/,
+        nullptr /*audio_mixer*/,
+        std::unique_ptr<cricket::MediaEngineInterface>(),
+        std::unique_ptr<webrtc::CallFactoryInterface>(),
+        std::unique_ptr<webrtc::RtcEventLogFactoryInterface>());
+#else
     const auto encoder_factory = new webrtc::VideoToolboxVideoEncoderFactory();
     const auto decoder_factory = new webrtc::VideoToolboxVideoDecoderFactory();
 
     // Ownership of encoder/decoder factories is passed on to the
     // peerconnectionfactory, that handles deleting them.
     _nativeFactory = webrtc::CreatePeerConnectionFactory(
         _networkThread.get(), _workerThread.get(), _signalingThread.get(),
         nullptr, encoder_factory, decoder_factory);
+#endif
     NSAssert(_nativeFactory, @"Failed to initialize PeerConnectionFactory!");
   }
   return self;
 }
 
 - (RTCAudioSource *)audioSourceWithConstraints:(nullable RTCMediaConstraints *)constraints {
   std::unique_ptr<webrtc::MediaConstraints> nativeConstraints;
   if (constraints) {
     nativeConstraints = constraints.nativeConstraints;
   }
   rtc::scoped_refptr<webrtc::AudioSourceInterface> source =
       _nativeFactory->CreateAudioSource(nativeConstraints.get());
   return [[RTCAudioSource alloc] initWithNativeAudioSource:source];
 }
 
 - (RTCAudioTrack *)audioTrackWithTrackId:(NSString *)trackId {
   RTCAudioSource *audioSource = [self audioSourceWithConstraints:nil];
   return [self audioTrackWithSource:audioSource trackId:trackId];
 }
 
 - (RTCAudioTrack *)audioTrackWithSource:(RTCAudioSource *)source
                                 trackId:(NSString *)trackId {
   return [[RTCAudioTrack alloc] initWithFactory:self
                                          source:source
                                         trackId:trackId];
 }
 
 - (RTCAVFoundationVideoSource *)avFoundationVideoSourceWithConstraints:
     (nullable RTCMediaConstraints *)constraints {
-  return [[RTCAVFoundationVideoSource alloc] initWithFactory:self
-                                                 constraints:constraints];
+#ifdef HAVE_NO_MEDIA
+  return nil;
+#else
+  return [[RTCAVFoundationVideoSource alloc] initWithFactory:self constraints:constraints];
+#endif
 }
 
 - (RTCVideoSource *)videoSource {
   rtc::scoped_refptr<webrtc::ObjcVideoTrackSource> objcVideoTrackSource(
       new rtc::RefCountedObject<webrtc::ObjcVideoTrackSource>());
   return [[RTCVideoSource alloc]
       initWithNativeVideoSource:webrtc::VideoTrackSourceProxy::Create(_signalingThread.get(),
                                                                       _workerThread.get(),
                                                                       objcVideoTrackSource)];
 }
@@ skipping 39 matching lines @@
   _hasStartedAecDump = _nativeFactory->StartAecDump(fd, maxSizeInBytes);
   return _hasStartedAecDump;
 }
 
 - (void)stopAecDump {
   _nativeFactory->StopAecDump();
   _hasStartedAecDump = NO;
 }
 
 @end