Build WebRTC with data channel only.

webrtc/media/BUILD.gn

 # Copyright (c) 2016 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("//build/config/linux/pkg_config.gni")
 import("../webrtc.gni")
@@ skipping 14 matching lines @@
 
 config("rtc_media_warnings_config") {
   # GN orders flags on a target before flags from configs. The default config
   # adds these flags so to cancel them out they need to come from a config and
   # cannot be on the target directly.
   if (!is_win) {
     cflags = [ "-Wno-deprecated-declarations" ]
   }
 }
 
-rtc_static_library("rtc_media_base") {
+rtc_source_set("rtc_media_audio_base") {
+  deps = [
+    "../api/audio_codecs:audio_codecs_api",
+  ]
+}
+
+rtc_source_set("rtc_media_video_base") {
+  deps = [
+    "../api:video_frame_api",
+    "../common_video:common_video",
+  ]
+}
+
+rtc_source_set("rtc_media_data_base") {

[the sun, 2017/05/29 13:55:32]

"..._data_base" sounds like "database" was misspelled. Suggest flipping these
names to "rtc_media_base_data" etc.

[Zhi Huang, 2017/05/31 00:03:28]

Done.

   # TODO(kjellander): Remove (bugs.webrtc.org/6828)
   # Enabling GN check triggers cyclic dependency error:
   #   //webrtc/media:rtc_media_base ->
   #   //webrtc/pc:rtc_pc ->
   #   //webrtc/media:media ->
   #   //webrtc/media:rtc_media_base
   check_includes = false
   defines = []
   libs = []
   deps = []
   sources = [
     "base/adaptedvideotracksource.cc",
     "base/adaptedvideotracksource.h",
     "base/audiosource.h",
     "base/codec.cc",
     "base/codec.h",
     "base/cryptoparams.h",
     "base/device.h",
+    "base/h264_profile_level_id.cc",
+    "base/h264_profile_level_id.h",
     "base/mediachannel.h",
     "base/mediaconstants.cc",
     "base/mediaconstants.h",
     "base/mediaengine.cc",
     "base/mediaengine.h",
     "base/rtpdataengine.cc",
     "base/rtpdataengine.h",
     "base/rtputils.cc",
     "base/rtputils.h",
     "base/streamparams.cc",
     "base/streamparams.h",
     "base/turnutils.cc",
     "base/turnutils.h",
     "base/videoadapter.cc",

[the sun, 2017/05/29 13:55:32]

The fact that there are things here in the "data" target concerning video and
audio is confusing. A comment would be good, or a separate sub target. It is
conceivable to want to build without data support as well.

[Zhi Huang, 2017/05/31 00:03:28]

Agreed. I'll leave a comment and a TODO here for now. It seems that it needs
more work to split them further without disabling the include header check.

     "base/videoadapter.h",
     "base/videobroadcaster.cc",
     "base/videobroadcaster.h",
     "base/videocapturer.cc",
     "base/videocapturer.h",
     "base/videocapturerfactory.h",
     "base/videocommon.cc",
     "base/videocommon.h",
     "base/videosourcebase.cc",
     "base/videosourcebase.h",
@@ skipping 13 matching lines @@
       "$rtc_libyuv_dir",
     ]
   } else {
     # Need to add a directory normally exported by libyuv.
     include_dirs += [ "$rtc_libyuv_dir/include" ]
   }
 
   deps += [
     "..:webrtc_common",
     "../api:libjingle_peerconnection_api",
-    "../api:video_frame_api",
-    "../api/audio_codecs:audio_codecs_api",
-    "../api/audio_codecs:builtin_audio_encoder_factory",
     "../base:rtc_base",
     "../base:rtc_base_approved",
     "../call:call_interfaces",
-    "../common_video:common_video",
     "../p2p",
   ]
 
   if (is_nacl) {
     deps += [ "//native_client_sdk/src/libraries/nacl_io" ]
   }
 }
 
-rtc_static_library("rtc_media") {
+rtc_static_library("rtc_media_base") {
+  public_deps = [
+    ":rtc_media_audio_base",
+    ":rtc_media_data_base",
+    ":rtc_media_video_base",
+  ]
+}
+
+rtc_static_library("rtc_audio_video") {
   # TODO(kjellander): Remove (bugs.webrtc.org/6828)
   # Enabling GN check triggers cyclic dependency error:
   #   //webrtc/media:media ->
   #   //webrtc/media:rtc_media ->
   #   //webrtc/pc:rtc_pc ->
   #   //webrtc/media:media
   check_includes = false

[kjellander_webrtc, 2017/06/01 05:34:30]

yay! less cycles. Thanks for that.

   defines = []
   libs = []
   deps = []
   sources = [
     "engine/adm_helpers.cc",
     "engine/adm_helpers.h",
     "engine/apm_helpers.cc",
     "engine/apm_helpers.h",
     "engine/internaldecoderfactory.cc",
     "engine/internaldecoderfactory.h",
@@ skipping 15 matching lines @@
     "engine/webrtcvideocapturer.h",
     "engine/webrtcvideocapturerfactory.cc",
     "engine/webrtcvideocapturerfactory.h",
     "engine/webrtcvideodecoderfactory.h",
     "engine/webrtcvideoencoderfactory.h",
     "engine/webrtcvideoengine2.cc",
     "engine/webrtcvideoengine2.h",
     "engine/webrtcvoe.h",
     "engine/webrtcvoiceengine.cc",
     "engine/webrtcvoiceengine.h",
-    "sctp/sctptransportinternal.h",
   ]
 
-  if (rtc_enable_sctp) {
-    sources += [
-      "sctp/sctptransport.cc",
-      "sctp/sctptransport.h",
-    ]
-  }
-
   configs += [ ":rtc_media_warnings_config" ]
 
   if (!build_with_chromium && is_clang) {
     # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
     suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
   }
 
   if (is_win) {
     cflags = [
       "/wd4245",  # conversion from "int" to "size_t", signed/unsigned mismatch.
@@ skipping 18 matching lines @@
   if (rtc_build_libyuv) {
     deps += [ "$rtc_libyuv_dir" ]
     public_deps = [
       "$rtc_libyuv_dir",
     ]
   } else {
     # Need to add a directory normally exported by libyuv.
     include_dirs += [ "$rtc_libyuv_dir/include" ]
   }
 
-  if (rtc_enable_sctp && rtc_build_usrsctp) {
-    include_dirs += [
-      # TODO(jiayl): move this into the public_configs of
-      # //third_party/usrsctp/BUILD.gn.
-      "//third_party/usrsctp/usrsctplib",
-    ]
-    deps += [ "//third_party/usrsctp" ]
-  }
-
   public_configs = []
   if (build_with_chromium) {
     deps += [ "../modules/video_capture:video_capture" ]
   } else {
     public_configs += [ ":rtc_media_defines_config" ]
     deps += [ "../modules/video_capture:video_capture_internal_impl" ]
   }
   deps += [
-    ":rtc_media_base",
+    ":rtc_media_audio_base",
+    ":rtc_media_data_base",
+    ":rtc_media_video_base",
     "..:webrtc_common",
     "../api:call_api",
     "../api:transport_api",
     "../api:video_frame_api",
     "../api/audio_codecs:audio_codecs_api",
     "../api/audio_codecs:builtin_audio_decoder_factory",
     "../api/video_codecs:video_codecs_api",
     "../base:rtc_base",
     "../base:rtc_base_approved",
     "../call",
     "../common_video:common_video",
     "../modules/audio_coding:rent_a_codec",
     "../modules/audio_device:audio_device",
     "../modules/audio_mixer:audio_mixer_impl",
     "../modules/audio_processing:audio_processing",
     "../modules/video_capture:video_capture_module",
     "../modules/video_coding",
     "../modules/video_coding:webrtc_h264",
     "../modules/video_coding:webrtc_vp8",
     "../modules/video_coding:webrtc_vp9",
     "../p2p:rtc_p2p",
     "../system_wrappers",
     "../video",
     "../voice_engine",
   ]
 }
 
+rtc_static_library("rtc_data") {
+  # TODO(kjellander): Remove (bugs.webrtc.org/6828)
+  # Enabling GN check triggers cyclic dependency error:

[kjellander_webrtc, 2017/05/29 20:59:15]

Is this comment still correct? I suspect you'll get another cycle if you enable
check_includes. 

[Zhi Huang, 2017/05/31 00:03:28]

We can enable the check here. The circular dependency only exists in
rtc_media_base_data.

[kjellander_webrtc, 2017/06/01 05:34:30]

Awesome.

+  #   //webrtc/media:media ->
+  #   //webrtc/media:rtc_media ->
+  #   //webrtc/pc:rtc_pc ->
+  #   //webrtc/media:media
+  check_includes = false
+  defines = []
+  deps = []
+
+  if (rtc_enable_sctp) {
+    sources = [
+      "sctp/sctptransport.cc",
+      "sctp/sctptransport.h",
+      "sctp/sctptransportinternal.h",
+    ]
+  }
+
+  configs += [ ":rtc_media_warnings_config" ]
+
+  if (!build_with_chromium && is_clang) {
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+    suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+  }
+
+  if (is_win) {
+    cflags = [
+      "/wd4245",  # conversion from "int" to "size_t", signed/unsigned mismatch.
+      "/wd4267",  # conversion from "size_t" to "int", possible loss of data.
+      "/wd4389",  # signed/unsigned mismatch.
+    ]
+  }
+
+  if (rtc_enable_sctp && rtc_build_usrsctp) {
+    include_dirs = [
+      # TODO(jiayl): move this into the public_configs of
+      # //third_party/usrsctp/BUILD.gn.
+      "//third_party/usrsctp/usrsctplib",
+    ]
+    deps += [ "//third_party/usrsctp" ]
+  }
+
+  deps += [
+    ":rtc_media_data_base",
+    "..:webrtc_common",
+    "../api:call_api",
+    "../api:transport_api",
+    "../base:rtc_base",
+    "../base:rtc_base_approved",
+    "../p2p:rtc_p2p",
+    "../system_wrappers",
+  ]
+}
+
+rtc_static_library("rtc_media") {
+  # TODO(kjellander): Remove (bugs.webrtc.org/6828)
+  # Enabling GN check triggers cyclic dependency error:

[kjellander_webrtc, 2017/05/29 20:59:15]

Is this comment still correct? I suspect you'll get another cycle if you enable
check_includes.  Please update it accordingly.

[Zhi Huang, 2017/05/31 00:03:28]

We can enable the check here. The circular dependency only exists in
rtc_media_base_data.

+  #   //webrtc/media:media ->
+  #   //webrtc/media:rtc_media ->
+  #   //webrtc/pc:rtc_pc ->
+  #   //webrtc/media:media
+  check_includes = false
+  public_deps = [
+    ":rtc_audio_video",
+    ":rtc_data",
+  ]
+}
+
 if (rtc_include_tests) {
   config("rtc_unittest_main_config") {
     # GN orders flags on a target before flags from configs. The default config
     # adds -Wall, and this flag have to be after -Wall -- so they need to
     # come from a config and can"t be on the target directly.
     if (is_clang && is_ios) {
       cflags = [ "-Wno-unused-variable" ]
     }
   }
 
@@ skipping 195 matching lines @@
       "../modules/video_coding:video_coding_utility",
       "../modules/video_coding:webrtc_vp8",
       "../p2p:p2p_test_utils",
       "../system_wrappers:metrics_default",
       "../test:audio_codec_mocks",
       "../test:test_support",
       "../voice_engine:voice_engine",
     ]
   }
 }