Build WebRTC with data channel only.

webrtc/pc/BUILD.gn

 # Copyright (c) 2016 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../webrtc.gni")
 if (is_android) {
   import("//build/config/android/config.gni")
   import("//build/config/android/rules.gni")
 }
 
 group("pc") {
   public_deps = [
     ":rtc_pc",
   ]
 }
 
 config("rtc_pc_config") {
   defines = []
   if (rtc_enable_sctp) {
     defines += [ "HAVE_SCTP" ]
   }
 }
 
-rtc_static_library("rtc_pc") {
+rtc_static_library("rtc_pc_base") {
   defines = []
   sources = [
     "audiomonitor.cc",
     "audiomonitor.h",
     "bundlefilter.cc",
     "bundlefilter.h",
     "channel.cc",
     "channel.h",
     "channelmanager.cc",
     "channelmanager.h",
@@ skipping 13 matching lines @@
     "srtpfilter.h",
     "voicechannel.h",
   ]
 
   deps = [
     "..:webrtc_common",
     "../api:call_api",
     "../api:libjingle_peerconnection_api",
     "../api:ortc_api",
     "../base:rtc_base",
-    "../common_video:common_video",
-    "../media",
+    "../base:rtc_task_queue",
+    "../media:rtc_data",
+    "../media:rtc_media_base_data",
     "../p2p:rtc_p2p",
   ]
 
   if (rtc_build_libsrtp) {
     deps += [ "//third_party/libsrtp" ]
   }
 
   public_configs = [ ":rtc_pc_config" ]
 
   if (!build_with_chromium && is_clang) {
     # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
     suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
   }
 }
 
+# TODO(zhihuang): Remove this once the downstream dependencies start using the
+# modular targets.
+rtc_source_set("rtc_pc") {
+  public_deps = [
+    ":rtc_pc_base",
+  ]
+
+  deps = [
+    "../media:rtc_audio_video",
+  ]
+}
+
 config("libjingle_peerconnection_warnings_config") {
   # GN orders flags on a target before flags from configs. The default config
   # adds these flags so to cancel them out they need to come from a config and
   # cannot be on the target directly.
   if (!is_win && !is_clang) {
     cflags = [ "-Wno-maybe-uninitialized" ]  # Only exists for GCC.
   }
 }
 
-rtc_static_library("libjingle_peerconnection") {
+# This target contains the null implementation of the audio module and it is
+# used to build WebRTC without audio support.
+rtc_static_library("pc_null_audio") {

[the sun, 2017/06/05 14:27:15]

This is much better, but there's still a little too much magic for my taste.

First, the file name "nullaudiofactory.cc" does not sound like it would contain
implementations of CreatePeerConnectionFactory() (neither does audiofactory.cc).

Second, we can do this without the "build-time polymorphism". :) If we removed
all but one of the CreatePeerConnectionFactory() declarations from
peerconnectioninterface.h and instead put them in separate .h/.cc/targets, the
client could just depend on the target which declares the CreatePCF() function
it needs. The resulting structure would be a simple tree. The CreatePCF() which
still lives in peerconnectioninterface.h is the one where everything can be
plugged in.

How the Create() methods should be clustered is not obvious to me, but note that
if we'd already had the above structure, a client with a different need could
have just rolled their own create method, pulling from the available
implementations of factories, loggers, etc.

[Zhi Huang, 2017/06/06 03:09:51]

Sorry that I didn't understand your previous suggestion correctly before.

I think the "build-time polymorphism" is what we need to make this approach
scalable. If we move the implementation of CreatePeerConnectionFactory method to
separate targets then we would need more special targets for different
functionalities (audio_only, video_only, audio_data etc.) in the future.

For an instance, once we have injectable video encoder/decoder in the future, we
would need four implementations in four build targets for the method
CreatePCF():

  CreatePCF(create_builtin_audio(), create_builtin_video()),
  CreatePCF(create_builtin_audio(), nullptr),
  CreatePCF(nullptr, create_builtin_video()),
  CreatePCF(nullptr. nullptr).

But with current approach, we only need an extra "null_audio" target which make
the create_builtin_audio() return a nullptr and an extra "null_video" target
which make create_builtin_video() return a nullptr.

Beside, wouldn't removing method declarations from peerconnectioninterface break
the downstream applications?

[the sun, 2017/06/06 19:30:33]

The point I'd like us to get to is to *not* maintain all these variants in the
webrtc tree, but to make it easy enough for clients to pull in things from the
api/ smorgasbord and plug together themselves. We'll keep a few commonly used
variants, and they can then serve as examples.

Less complexity, less work, more flexibility, for more clients.
Maybe temporarily. What we could do to avoid breakage:

1. peerconnectioninterface.h in a new target which is also considered public.
2. Keep only the largest-superset incarnation of CreatePCF in it.
3. Keep existing CreatePCF in the current target, which then depends on the new
target
4. Add new targets for the commonly used CreatePCF methods we decide that we
need.

+  sources = [
+    "nullaudiofactory.cc",
+  ]
+
+  if (!build_with_chromium && is_clang) {
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+    suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+  }
+
+  deps = [
+    "../api:libjingle_peerconnection_api",
+    "../base:rtc_base",
+    "../base:rtc_base_approved",
+  ]
+}
+
+# This target contains the real implementation of the audio module and it is
+# used to build WebRTC with audio support. It should never be used with
+# "pc_null_audio" at the same time and it should always be linked with the
+# "pc_media".
+rtc_static_library("pc_audio") {
+  sources = [
+    "audiofactory.cc",
+  ]
+
+  deps = [
+    "../api:audio_mixer_api",
+    "../api:libjingle_peerconnection_api",
+    "../api/audio_codecs:audio_codecs_api",
+    "../api/audio_codecs:builtin_audio_decoder_factory",
+    "../api/audio_codecs:builtin_audio_encoder_factory",
+    "../base:rtc_base",
+    "../base:rtc_base_approved",
+    "../media:rtc_audio_video",
+    "../modules/audio_device:audio_device",
+  ]
+
+  if (!build_with_chromium && is_clang) {
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+    suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+  }
+}
+
+# This target contains the null implementation of the audio/video related
+# objects and it is used to build WebRTC without audio and video support.
+rtc_source_set("pc_null_media") {
+  sources = [
+    "nullmediafactory.cc",
+  ]
+
+  if (!build_with_chromium && is_clang) {
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+    suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+  }
+
+  deps = [
+    "../logging:rtc_event_log_api",
+  ]
+}
+
+# This target contains the real implementation of the audio/video related
+# objects and it is used to build WebRTC with audio and video support.
+rtc_source_set("pc_media") {
+  deps = [
+    "../call",
+    "../media:rtc_audio_video",
+  ]
+
+  if (!build_with_chromium && is_clang) {
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+    suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+  }
+}
+
+# The modular build targets can be used to build WebRTC with different
+# functionalities. The users can choose either the real implemenation
+# or the null implementation of the audio/video modules based on their
+# requirements.
+#
+# For example, to build WebRTC with datachannel support only, we would need the
+# the peerconnection and the null implementation of the audio and video modules.
+#
+# rtc_source_set("datachannel_only") {
+#    deps = [
+#      ":pc_null_audio",
+#      ":pc_null_media",
+#      ":peerconnection",
+#    ]
+# }
+#
+# To build WebRTC with all the audio, video and datachannel support, we would
+# need the peerconnection and the real implementation of the audio and video
+# modules.
+#
+# rtc_source_set("full") {
+#    deps = [
+#      ":pc_audio",
+#      ":pc_media",
+#      ":peerconnection",
+#    ]
+# }
+rtc_static_library("peerconnection") {
   cflags = []
   sources = [
     "audiotrack.cc",
     "audiotrack.h",
     "datachannel.cc",
     "datachannel.h",
     "dtmfsender.cc",
     "dtmfsender.h",
     "iceserverparsing.cc",
     "iceserverparsing.h",
@@ skipping 40 matching lines @@
   ]
 
   configs += [ ":libjingle_peerconnection_warnings_config" ]
 
   if (!build_with_chromium && is_clang) {
     # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
     suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
   }
 
   deps = [
-    ":rtc_pc",
+    ":rtc_pc_base",
     "..:webrtc_common",
     "../api:call_api",
     "../api:rtc_stats_api",
-    "../api/audio_codecs:builtin_audio_decoder_factory",
-    "../api/audio_codecs:builtin_audio_encoder_factory",
     "../api/video_codecs:video_codecs_api",
     "../base:rtc_base",
     "../base:rtc_base_approved",
-    "../call",
+    "../call:call_interfaces",
     "../logging:rtc_event_log_api",
-    "../media",
-    "../modules/audio_device:audio_device",
+    "../media:rtc_data",
+    "../media:rtc_media_base_data",
     "../p2p:rtc_p2p",
     "../stats",
     "../system_wrappers:system_wrappers",
   ]
 
   public_deps = [
     "../api:libjingle_peerconnection_api",
   ]
+}
+
+# TODO(zhihuang): Remove this once the downstream dependencies start using the
+# modular targets.
+rtc_source_set("libjingle_peerconnection") {
+  public_deps = [
+    ":pc_audio",
+    ":pc_media",
+    ":peerconnection",
+    "../api:libjingle_peerconnection_api",
+  ]
 
   if (rtc_use_quic) {
     sources += [
       "quicdatachannel.cc",
       "quicdatachannel.h",
       "quicdatatransport.cc",
       "quicdatatransport.h",
     ]
     deps += [ "//third_party/libquic" ]
     public_deps = [
@@ skipping 57 matching lines @@
     if (rtc_build_libsrtp) {
       deps += [ "//third_party/libsrtp" ]
     }
 
     if (is_android) {
       deps += [ "//testing/android/native_test:native_test_support" ]
     }
   }
 
   rtc_source_set("pc_test_utils") {
+    # Cannot have GN check enabled because this target would also be used in the
+    # "peerconnection_datachannelonly_unittests" and we don't want to depend on
+    # the target "media:rtc_media_tests_utils" indrectly since it contains all
+    # the audio and video related classes.
+    # TODO(zhihuang): Enable the check once the "media:rtc_media_tests_utils" is
+    # broken down to modular sub-targets.
+    check_includes = false
     testonly = true
     sources = [
       "test/fakeaudiocapturemodule.cc",
       "test/fakeaudiocapturemodule.h",
       "test/fakedatachannelprovider.h",
       "test/fakeperiodicvideocapturer.h",
       "test/fakertccertificategenerator.h",
       "test/fakevideotrackrenderer.h",
       "test/fakevideotracksource.h",
       "test/mock_datachannel.h",
       "test/mock_peerconnection.h",
       "test/mock_webrtcsession.h",
       "test/mockpeerconnectionobservers.h",
       "test/peerconnectiontestwrapper.cc",
       "test/peerconnectiontestwrapper.h",
       "test/rtcstatsobtainer.h",
       "test/testsdpstrings.h",
     ]
 
     deps = [
-      ":libjingle_peerconnection",
+      ":peerconnection",
       "..:webrtc_common",
       "../api:libjingle_peerconnection_test_api",
       "../api:rtc_stats_api",
       "../base:rtc_base",
       "../base:rtc_base_approved",
       "../base:rtc_base_tests_utils",
-      "../media:rtc_media",
-      "../media:rtc_media_tests_utils",
       "../modules/audio_device:audio_device",
       "../p2p:p2p_test_utils",
       "../test:test_support",
       "//testing/gmock",
     ]
 
     if (!build_with_chromium && is_clang) {
       # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
       suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
     }
@@ skipping 105 matching lines @@
       "../system_wrappers:metrics_default",
       "//testing/gmock",
     ]
 
     if (is_android) {
       deps += [ "//testing/android/native_test:native_test_support" ]
 
       shard_timeout = 900
     }
   }
+
+  rtc_test("peerconnection_datachannelonly_unittests") {
+    check_includes = false  # TODO(zhihuang): Remove (bugs.webrtc.org/6828)
+    testonly = true
+    sources = [
+      "peerconnection_datachannelonly_unittest.cc",
+    ]
+
+    configs += [ ":peerconnection_unittests_config" ]
+
+    if (!build_with_chromium && is_clang) {
+      # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+      suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+    }
+
+    # TODO(jschuh): Bug 1348: fix this warning.
+    configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
+
+    if (is_win) {
+      cflags = [
+        "/wd4245",  # conversion from int to size_t, signed/unsigned mismatch.
+        "/wd4389",  # signed/unsigned mismatch.
+      ]
+    }
+
+    deps = []
+    if (is_android) {
+      sources += [
+        "test/androidtestinitializer.cc",
+        "test/androidtestinitializer.h",
+      ]
+      deps += [
+        "//testing/android/native_test:native_test_support",
+        "//webrtc/sdk/android:base_jni",
+        "//webrtc/sdk/android:libjingle_peerconnection_java",
+        "//webrtc/sdk/android:null_audio_jni",
+        "//webrtc/sdk/android:null_video_jni",
+      ]
+    }
+
+    deps += [
+      ":pc_null_audio",
+      ":pc_null_media",
+      ":pc_test_utils",
+      ":peerconnection",
+      "..:webrtc_common",
+      "../api:fakemetricsobserver",
+      "../base:rtc_base_approved",
+      "../base:rtc_base_tests_main",
+      "../base:rtc_base_tests_utils",
+      "../modules/utility",
+      "../pc:rtc_pc_base",
+      "../system_wrappers:metrics_default",
+      "//testing/gmock",
+    ]
+
+    if (is_android) {
+      deps += [ "//testing/android/native_test:native_test_support" ]
+      shard_timeout = 900
+    }
+  }
 }