Enable GN check for webrtc/logging

webrtc/logging/BUILD.gn

 # Copyright (c) 2016 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../webrtc.gni")
 import("//third_party/protobuf/proto_library.gni")
 if (is_android) {
   import("//build/config/android/config.gni")
   import("//build/config/android/rules.gni")
 }
 
 group("logging") {
   public_deps = [
     ":rtc_event_log_impl",
   ]
   if (rtc_enable_protobuf) {
     public_deps += [ ":rtc_event_log_parser" ]
   }
 }
 
 rtc_source_set("rtc_event_log_api") {
+  # TODO(kjellander): Remove (bugs.webrtc.org/6828)
+  # Enabling GN check triggers cyclic dependency error:
+  #  //webrtc/logging:rtc_event_log_api ->
+  #  //webrtc/modules/audio_coding:audio_network_adaptor ->
+  #  //webrtc/logging:rtc_event_log_api
+  check_includes = false

[terelius, 2017/02/27 17:26:16]

I don't think this should be needed. I've filed a separate bug to track this
cyclic dependency. https://bugs.chromium.org/p/webrtc/issues/detail?id=7257

[kjellander_webrtc, 2017/02/27 22:43:28]

It is. If I remove it I have to add 
//webrtc/modules/audio_coding:audio_network_adaptor
which in turn will cause the cycle described above. Thanks for filing the bug; I
added a reference to it.

   sources = [
     "rtc_event_log/rtc_event_log.h",
   ]
+  deps = [
+    "../base:rtc_base_approved",
+    "../call:call_interfaces",
+    "../system_wrappers",

[terelius, 2017/02/27 17:26:16]

Why do we need system_wrappers?

[kjellander_webrtc, 2017/02/27 22:43:28]

Good catch. It seems this particular one is not needed. I must have added it by
accident here when I fixed the missing dependencies below (where it's actually
needed). 

Removed it now.

+  ]
 }
 
 rtc_static_library("rtc_event_log_impl") {
   sources = [
     "rtc_event_log/ringbuffer.h",
     "rtc_event_log/rtc_event_log.cc",
     "rtc_event_log/rtc_event_log_helper_thread.cc",
     "rtc_event_log/rtc_event_log_helper_thread.h",
   ]
 
   defines = []
 
   deps = [
     ":rtc_event_log_api",
     "..:webrtc_common",
+    "../base:rtc_base_approved",
     "../call:call_interfaces",
     "../modules/audio_coding:audio_network_adaptor",
     "../modules/rtp_rtcp",
+    "../system_wrappers",
   ]
 
   if (rtc_enable_protobuf) {
     defines += [ "ENABLE_RTC_EVENT_LOG" ]
     deps += [ ":rtc_event_log_proto" ]
   }
   if (!build_with_chromium && is_clang) {
     # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
     suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
   }
 }
 
 if (rtc_enable_protobuf) {
   proto_library("rtc_event_log_proto") {
     sources = [
       "rtc_event_log/rtc_event_log.proto",
     ]
     proto_out_dir = "webrtc/logging/rtc_event_log"
   }
 
   rtc_static_library("rtc_event_log_parser") {
     sources = [
       "rtc_event_log/rtc_event_log_parser.cc",
       "rtc_event_log/rtc_event_log_parser.h",
     ]
 
     public_deps = [
+      ":rtc_event_log_api",
       ":rtc_event_log_proto",
       "..:webrtc_common",
+      "../call:call_interfaces",
+      "../modules/rtp_rtcp:rtp_rtcp",
+      "../system_wrappers",
     ]
 
     if (!build_with_chromium && is_clang) {
       # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
       suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
     }
+    deps = [
+      "../base:rtc_base_approved",
+    ]
   }
 
   if (rtc_include_tests) {
     rtc_source_set("rtc_event_log_tests") {
       testonly = true
       sources = [
         "rtc_event_log/ringbuffer_unittest.cc",
         "rtc_event_log/rtc_event_log_unittest.cc",
         "rtc_event_log/rtc_event_log_unittest_helper.cc",
       ]
       deps = [
         ":rtc_event_log_impl",
         ":rtc_event_log_parser",
+        "../base:rtc_base_approved",
+        "../base:rtc_base_tests_utils",
         "../call",
         "../modules/rtp_rtcp",
         "../system_wrappers:metrics_default",
+        "../test:test_support",
         "//testing/gmock",
         "//testing/gtest",
       ]
       if (!build_with_chromium && is_clang) {
         # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
         suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
       }
     }
     rtc_test("rtc_event_log2rtp_dump") {
       testonly = true
@@ skipping 22 matching lines @@
     rtc_executable("rtc_event_log2text") {
       testonly = true
       sources = [
         "rtc_event_log/rtc_event_log2text.cc",
       ]
       deps = [
         ":rtc_event_log_api",
         ":rtc_event_log_impl",
         ":rtc_event_log_parser",
         "../base:rtc_base_approved",
+        "../call:call_interfaces",
 
         # TODO(kwiberg): Remove this dependency.
         "../api/audio_codecs:audio_codecs_api",
         "../modules/rtp_rtcp:rtp_rtcp",
         "//third_party/gflags",
       ]
       if (!build_with_chromium && is_clang) {
         # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
         suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
       }
     }
   }
 }