Implement new PeerConnection certificate policy API in ObjC API

webrtc/sdk/objc/Framework/Classes/RTCIceServer.mm

Index: webrtc/sdk/objc/Framework/Classes/RTCIceServer.mm
diff --git a/webrtc/sdk/objc/Framework/Classes/RTCIceServer.mm b/webrtc/sdk/objc/Framework/Classes/RTCIceServer.mm
index 41084b9357129f126f6683047f4ea748124b8216..fb4b493b0f1ef64280317098d5576b9a9af801b5 100644
--- a/webrtc/sdk/objc/Framework/Classes/RTCIceServer.mm
+++ b/webrtc/sdk/objc/Framework/Classes/RTCIceServer.mm
@@ -17,9 +17,9 @@
 @synthesize urlStrings = _urlStrings;
 @synthesize username = _username;
 @synthesize credential = _credential;
+@synthesize tlsCertPolicy = _tlsCertPolicy;
 
 - (instancetype)initWithURLStrings:(NSArray<NSString *> *)urlStrings {
-  NSParameterAssert(urlStrings.count);
   return [self initWithURLStrings:urlStrings
                          username:nil
                        credential:nil];
@@ -28,20 +28,42 @@
 - (instancetype)initWithURLStrings:(NSArray<NSString *> *)urlStrings
                           username:(NSString *)username
                         credential:(NSString *)credential {
+  return [self initWithURLStrings:urlStrings
+                         username:username
+                       credential:credential
+                    tlsCertPolicy:RTCTlsCertPolicySecure];
+}
+
+- (instancetype)initWithURLStrings:(NSArray<NSString *> *)urlStrings
+                          username:(NSString *)username
+                        credential:(NSString *)credential
+                     tlsCertPolicy:(RTCTlsCertPolicy)tlsCertPolicy {
   NSParameterAssert(urlStrings.count);
   if (self = [super init]) {
     _urlStrings = [[NSArray alloc] initWithArray:urlStrings copyItems:YES];
     _username = [username copy];
     _credential = [credential copy];
+    _tlsCertPolicy = tlsCertPolicy;
   }
   return self;
 }
 
+- (NSString*)describeTlsCertPolicy:(RTCTlsCertPolicy)tlsCertPolicy {

[tkchin_webrtc, 2017/02/02 17:54:00]

nit: (NSString *)

to follow other places in the source:
- (NSString *)stringForTlsCertPolicy;

and place in private section

[hnsl1, 2017/02/02 19:50:08]

Done.

+  switch (tlsCertPolicy) {
+    case RTCTlsCertPolicySecure:
+      return @"RTCTlsCertPolicySecure";
+    case RTCTlsCertPolicyInsecureNoCheck:
+      return @"RTCTlsCertPolicyInsecureNoCheck";
+    default:
+      return @"RTCTlsCertPolicyUnknown";
+  }
+}
+
 - (NSString *)description {
-  return [NSString stringWithFormat:@"RTCIceServer:\n%@\n%@\n%@",
-                                    _urlStrings,
-                                    _username,
-                                    _credential];
+  return
+      [NSString stringWithFormat:@"RTCIceServer:\n%@\n%@\n%@\n%@", _urlStrings,
+                                 _username, _credential,
+                                 [self describeTlsCertPolicy:_tlsCertPolicy]];
 }
 
 #pragma mark - Private
@@ -57,6 +79,21 @@
                                             BOOL *stop) {
     iceServer.urls.push_back(url.stdString);
   }];
+
+  switch (_tlsCertPolicy) {
+    case RTCTlsCertPolicySecure:
+      iceServer.tls_cert_policy =
+          webrtc::PeerConnectionInterface::kTlsCertPolicySecure;
+      break;
+    case RTCTlsCertPolicyInsecureNoCheck:
+      iceServer.tls_cert_policy =
+          webrtc::PeerConnectionInterface::kTlsCertPolicyInsecureNoCheck;
+      break;
+    default:

[tkchin_webrtc, 2017/02/02 17:54:00]

remove default case so that compiler will complain when new enum is added

[hnsl1, 2017/02/02 19:50:08]

Done.

+      iceServer.tls_cert_policy =
+          webrtc::PeerConnectionInterface::kTlsCertPolicySecure;
+      break;
+  }
   return iceServer;
 }
 
@@ -69,9 +106,24 @@
   }
   NSString *username = [NSString stringForStdString:nativeServer.username];
   NSString *credential = [NSString stringForStdString:nativeServer.password];
+  RTCTlsCertPolicy tlsCertPolicy;
+
+  switch (nativeServer.tls_cert_policy) {
+    case webrtc::PeerConnectionInterface::kTlsCertPolicySecure:
+      tlsCertPolicy = RTCTlsCertPolicySecure;
+      break;
+    case webrtc::PeerConnectionInterface::kTlsCertPolicyInsecureNoCheck:
+      tlsCertPolicy = RTCTlsCertPolicyInsecureNoCheck;
+      break;
+    default:

[tkchin_webrtc, 2017/02/02 17:54:00]

ditto

[hnsl1, 2017/02/02 19:50:08]

Done.

+      tlsCertPolicy = RTCTlsCertPolicySecure;
+      break;
+  }
+
   self = [self initWithURLStrings:urls
                          username:username
-                       credential:credential];
+                       credential:credential
+                    tlsCertPolicy:tlsCertPolicy];
   return self;
 }