Implement new PeerConnection certificate policy API in ObjC API

webrtc/sdk/objc/Framework/Classes/RTCIceServer.mm

 /*
  *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
  *
  *  Use of this source code is governed by a BSD-style license
  *  that can be found in the LICENSE file in the root of the source
  *  tree. An additional intellectual property rights grant can be found
  *  in the file PATENTS.  All contributing project authors may
  *  be found in the AUTHORS file in the root of the source tree.
  */
 
 #import "RTCIceServer+Private.h"
 
 #import "NSString+StdString.h"
 
 @implementation RTCIceServer
 
 @synthesize urlStrings = _urlStrings;
 @synthesize username = _username;
 @synthesize credential = _credential;
+@synthesize tlsCertPolicy = _tlsCertPolicy;
 
 - (instancetype)initWithURLStrings:(NSArray<NSString *> *)urlStrings {
   NSParameterAssert(urlStrings.count);
   return [self initWithURLStrings:urlStrings
                          username:nil
                        credential:nil];
 }
 
 - (instancetype)initWithURLStrings:(NSArray<NSString *> *)urlStrings
                           username:(NSString *)username
                         credential:(NSString *)credential {
   NSParameterAssert(urlStrings.count);
+  return [self initWithURLStrings:urlStrings
+                         username:username
+                       credential:credential
+                    tlsCertPolicy:RTCTlsCertPolicySecure];
+}
+
+- (instancetype)initWithURLStrings:(NSArray<NSString*>*)urlStrings
+                          username:(NSString*)username
+                        credential:(NSString*)credential
+                     tlsCertPolicy:(RTCTlsCertPolicy)tlsCertPolicy {
+  NSParameterAssert(urlStrings.count);
   if (self = [super init]) {
     _urlStrings = [[NSArray alloc] initWithArray:urlStrings copyItems:YES];
     _username = [username copy];
     _credential = [credential copy];
+    _tlsCertPolicy = tlsCertPolicy;
   }
   return self;
 }
 
 - (NSString *)description {
-  return [NSString stringWithFormat:@"RTCIceServer:\n%@\n%@\n%@",
-                                    _urlStrings,
-                                    _username,
-                                    _credential];
+  return [NSString stringWithFormat:@"RTCIceServer:\n%@\n%@\n%@\n%lu",
+                                    _urlStrings, _username, _credential,
+                                    (unsigned long)_tlsCertPolicy];
 }
 
 #pragma mark - Private
 
 - (webrtc::PeerConnectionInterface::IceServer)nativeServer {
   __block webrtc::PeerConnectionInterface::IceServer iceServer;
 
   iceServer.username = [NSString stdStringForString:_username];
   iceServer.password = [NSString stdStringForString:_credential];
 
   [_urlStrings enumerateObjectsUsingBlock:^(NSString *url,
                                             NSUInteger idx,
                                             BOOL *stop) {
     iceServer.urls.push_back(url.stdString);
   }];
+
+  if (_tlsCertPolicy == RTCTlsCertPolicySecure) {
+    iceServer.tls_cert_policy =
+        webrtc::PeerConnectionInterface::kTlsCertPolicySecure;
+  } else if (_tlsCertPolicy == RTCTlsCertPolicyInsecureNoCheck) {
+    iceServer.tls_cert_policy =
+        webrtc::PeerConnectionInterface::kTlsCertPolicyInsecureNoCheck;
+  } else {

[daniela-webrtc, 2017/02/01 14:26:53]

I don't think this else will ever be executed.

[hnsl1, 2017/02/01 16:11:47]

Done.

+    iceServer.tls_cert_policy =
+        webrtc::PeerConnectionInterface::kTlsCertPolicySecure;
+  }
   return iceServer;
 }
 
 - (instancetype)initWithNativeServer:
     (webrtc::PeerConnectionInterface::IceServer)nativeServer {
   NSMutableArray *urls =
       [NSMutableArray arrayWithCapacity:nativeServer.urls.size()];
   for (auto const &url : nativeServer.urls) {
     [urls addObject:[NSString stringForStdString:url]];
   }
   NSString *username = [NSString stringForStdString:nativeServer.username];
   NSString *credential = [NSString stringForStdString:nativeServer.password];
+  RTCTlsCertPolicy tlsCertPolicy;
+
+  if (nativeServer.tls_cert_policy ==
+      webrtc::PeerConnectionInterface::kTlsCertPolicySecure) {
+    tlsCertPolicy = RTCTlsCertPolicySecure;
+  } else if (nativeServer.tls_cert_policy ==
+             webrtc::PeerConnectionInterface::kTlsCertPolicyInsecureNoCheck) {
+    tlsCertPolicy = RTCTlsCertPolicyInsecureNoCheck;
+  } else {

[daniela-webrtc, 2017/02/01 14:26:53]

Same here

[hnsl1, 2017/02/01 16:11:47]

Done.

+    tlsCertPolicy = RTCTlsCertPolicySecure;
+  }
+
   self = [self initWithURLStrings:urls
                          username:username
-                       credential:credential];
+                       credential:credential
+                    tlsCertPolicy:tlsCertPolicy];
   return self;
 }
 
 @end