Move FilePlayer and FileRecorder to Voice Engine

webrtc/voice_engine/BUILD.gn

 # Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../build/webrtc.gni")
 
+rtc_static_library("audio_coder") {

[the sun, 2017/01/09 12:44:43]

Do we really benefit from having separate targets for these? can we just add the
files to the voice_engine static lib? It seems to pull in the same deps, and
also, "file_player_unittest.cc" is included in voice_engine_unittests.

[kwiberg-webrtc, 2017/01/09 12:53:55]

Grouping them by themselves like this makes it easier to see what pieces there
are, instead of just seeing it as one big Voice Engine pile. In particular, it's
now obvious at a glance which source files are responsible for which
dependencies.

There are currently two more advantages that will eventually go away: I was able
to easily mark the new targets as being subject to "gn check", and will easily
be able to fix the find_bad_constructs errors and remove the suppressions. Being
able to do this for several small targets, one by one, rather than having to do
it for giant targets increases the chance that it gets done.

[kjellander_webrtc, 2017/01/09 15:17:21]

Nice, I like small targets. There are many benefits with that and you already
mentioned a few of them.

+  sources = [
+    "coder.cc",
+    "coder.h",
+  ]
+  deps = [
+    "..:webrtc_common",
+    "../modules/audio_coding",
+    "../modules/audio_coding:audio_format_conversion",
+    "../modules/audio_coding:builtin_audio_decoder_factory",
+    "../modules/audio_coding:rent_a_codec",
+  ]
+
+  if (!build_with_chromium && is_clang) {
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+    suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+  }
+}
+
+rtc_static_library("file_player") {
+  sources = [
+    "file_player.cc",
+    "file_player.h",
+  ]
+  deps = [
+    ":audio_coder",
+    "..:webrtc_common",
+    "../common_audio",
+    "../modules/media_file",
+    "../system_wrappers",
+  ]
+
+  if (!build_with_chromium && is_clang) {
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+    suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+  }
+}
+
+rtc_static_library("file_recorder") {
+  sources = [
+    "file_recorder.cc",
+    "file_recorder.h",
+  ]
+  deps = [
+    ":audio_coder",
+    "..:webrtc_common",
+    "../base:rtc_base_approved",
+    "../common_audio",
+    "../modules/media_file:media_file",
+    "../system_wrappers",
+  ]
+
+  if (!build_with_chromium && is_clang) {
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+    suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+  }
+}
+
 rtc_static_library("voice_engine") {
   sources = [
     "channel.cc",
     "channel.h",
     "channel_manager.cc",
     "channel_manager.h",
     "channel_proxy.cc",
     "channel_proxy.h",
     "include/voe_audio_processing.h",
     "include/voe_base.h",
@@ skipping 57 matching lines @@
 
   if (!build_with_chromium && is_clang) {
     # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
     suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
   }
 
   public_deps = [
     "../modules/audio_coding",
   ]
   deps = [
+    ":file_player",
+    ":file_recorder",
     ":level_indicator",
     "..:webrtc_common",
     "../api:audio_mixer_api",
     "../api:call_api",
     "../api:transport_api",
     "../audio/utility:audio_frame_operations",
     "../base:rtc_base_approved",
     "../common_audio",
     "../logging:rtc_event_log_api",
     "../modules/audio_coding:audio_decoder_factory_interface",
@@ skipping 86 matching lines @@
       "//testing/gtest",
     ]
   }
 
   rtc_test("voice_engine_unittests") {
     deps = [
       ":channel_transport",
       ":voice_engine",
       "//testing/gmock",
       "//testing/gtest",
+      "//third_party/gflags",
       "//webrtc/common_audio",
       "//webrtc/modules/audio_coding",
       "//webrtc/modules/audio_conference_mixer",
       "//webrtc/modules/audio_device",
       "//webrtc/modules/audio_processing",
       "//webrtc/modules/media_file",
       "//webrtc/modules/rtp_rtcp",
       "//webrtc/modules/utility",
       "//webrtc/system_wrappers",
       "//webrtc/test:test_main",
     ]
 
     if (is_android) {
       deps += [ "//testing/android/native_test:native_test_native_code" ]
       shard_timeout = 900
     }
 
     sources = [
       "channel_unittest.cc",
+      "file_player_unittests.cc",
       "test/channel_transport/udp_socket_manager_unittest.cc",
       "test/channel_transport/udp_socket_wrapper_unittest.cc",
       "test/channel_transport/udp_transport_unittest.cc",
       "transmit_mixer_unittest.cc",
       "utility_unittest.cc",
       "voe_audio_processing_unittest.cc",
       "voe_base_unittest.cc",
       "voe_codec_unittest.cc",
       "voe_network_unittest.cc",
       "voice_engine_fixture.cc",
       "voice_engine_fixture.h",
     ]
 
+    data = [
+      "//resources/utility/encapsulated_pcm16b_8khz.wav",
+      "//resources/utility/encapsulated_pcmu_8khz.wav",
+    ]
+
     if (is_win) {
       defines = [ "WEBRTC_DRIFT_COMPENSATION_SUPPORTED" ]
 
       cflags = [
         # TODO(kjellander): Bug 261: fix this warning.
         "/wd4373",  # Virtual function override.
       ]
     }
 
     if (!build_with_chromium && is_clang) {
@@ skipping 111 matching lines @@
         ]
       }
 
       if (!build_with_chromium && is_clang) {
         # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
         suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
       }
     }
   }
 }