Move /webrtc/api/android files to /webrtc/sdk/android

webrtc/sdk/android/BUILD.gn

+# Copyright (c) 2016 The WebRTC project authors. All Rights Reserved.
+#
+# Use of this source code is governed by a BSD-style license
+# that can be found in the LICENSE file in the root of the source
+# tree. An additional intellectual property rights grant can be found
+# in the file PATENTS.  All contributing project authors may
+# be found in the AUTHORS file in the root of the source tree.
+
+import("//webrtc/build/webrtc.gni")
+import("//build/config/android/config.gni")
+import("//build/config/android/rules.gni")
+
+group("android") {

[sakal, 2016/12/05 11:51:58]

I don't think this group makes sense right now. It is not used right? In the
future, it might be a target for a jar file that has both the Java and JNI.

[magjed_webrtc, 2016/12/05 13:56:53]

Done.

+  public_deps = [
+    ":libjingle_peerconnection_java",
+    ":libjingle_peerconnection_so",
+  ]
+}
+
+config("libjingle_peerconnection_jni_warnings_config") {
+  # The warnings below are enabled by default. Since GN orders compiler flags
+  # for a target before flags from configs, the only way to disable such
+  # warnings is by having them in a separate config, loaded from the target.
+  if (!is_win) {
+    cflags = [
+      "-Wno-sign-compare",
+      "-Wno-unused-variable",
+    ]
+  }
+}
+
+rtc_static_library("libjingle_peerconnection_jni") {
+  sources = [
+    "src/jni/androidhistogram_jni.cc",
+    "src/jni/androidmediacodeccommon.h",
+    "src/jni/androidmediadecoder_jni.cc",
+    "src/jni/androidmediadecoder_jni.h",
+    "src/jni/androidmediaencoder_jni.cc",
+    "src/jni/androidmediaencoder_jni.h",
+    "src/jni/androidnetworkmonitor_jni.cc",
+    "src/jni/androidnetworkmonitor_jni.h",
+    "src/jni/androidvideotracksource.cc",
+    "src/jni/androidvideotracksource.h",
+    "src/jni/androidvideotracksource_jni.cc",
+    "src/jni/classreferenceholder.cc",
+    "src/jni/classreferenceholder.h",
+    "src/jni/jni_helpers.cc",
+    "src/jni/jni_helpers.h",
+    "src/jni/native_handle_impl.cc",
+    "src/jni/native_handle_impl.h",
+    "src/jni/peerconnection_jni.cc",
+    "src/jni/surfacetexturehelper_jni.cc",
+    "src/jni/surfacetexturehelper_jni.h",
+  ]
+
+  configs += [ ":libjingle_peerconnection_jni_warnings_config" ]
+
+  if (is_clang) {
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+    suppressed_configs += [
+      "//build/config/clang:extra_warnings",
+      "//build/config/clang:find_bad_constructs",
+    ]
+  }
+
+  # TODO(jschuh): Bug 1348: fix this warning.
+  configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
+
+  if (is_win) {
+    cflags += [
+      "/wd4245",  # conversion from "int" to "size_t", signed/unsigned mismatch.
+      "/wd4389",  # signed/unsigned mismatch.
+    ]
+  }
+
+  deps = [
+    "//webrtc/api:libjingle_peerconnection",
+  ]
+
+  if (rtc_build_libyuv) {
+    deps += [ "$rtc_libyuv_dir" ]
+    public_deps = [
+      "$rtc_libyuv_dir",
+    ]
+  } else {
+    # Need to add a directory normally exported by libyuv.
+    include_dirs = [ "$rtc_libyuv_dir/include" ]
+  }
+}
+
+rtc_static_library("libjingle_peerconnection_metrics_default_jni") {
+  sources = [
+    "src/jni/androidmetrics_jni.cc",
+  ]
+
+  configs += [ ":libjingle_peerconnection_jni_warnings_config" ]
+
+  deps = [
+    "//webrtc/api:libjingle_peerconnection",
+    "//webrtc/system_wrappers:field_trial_default",
+    "//webrtc/system_wrappers:metrics_default",
+  ]
+}
+
+rtc_shared_library("libjingle_peerconnection_so") {
+  sources = [
+    "src/jni/jni_onload.cc",
+  ]
+
+  suppressed_configs += [ "//build/config/android:hide_native_jni_exports" ]
+
+  deps = [
+    ":libjingle_peerconnection_jni",
+    ":libjingle_peerconnection_metrics_default_jni",
+    "//webrtc/api:libjingle_peerconnection",
+  ]
+  output_extension = "so"
+}
+
+android_library("libjingle_peerconnection_java") {
+  java_files = [
+    "//webrtc/modules/audio_device/android/java/src/org/webrtc/voiceengine/BuildInfo.java",
+    "//webrtc/modules/audio_device/android/java/src/org/webrtc/voiceengine/WebRtcAudioEffects.java",
+    "//webrtc/modules/audio_device/android/java/src/org/webrtc/voiceengine/WebRtcAudioManager.java",
+    "//webrtc/modules/audio_device/android/java/src/org/webrtc/voiceengine/WebRtcAudioRecord.java",
+    "//webrtc/modules/audio_device/android/java/src/org/webrtc/voiceengine/WebRtcAudioTrack.java",
+    "//webrtc/modules/audio_device/android/java/src/org/webrtc/voiceengine/WebRtcAudioUtils.java",
+    "src/java/org/webrtc/AudioSource.java",
+    "src/java/org/webrtc/AudioTrack.java",
+    "src/java/org/webrtc/CallSessionFileRotatingLogSink.java",
+    "src/java/org/webrtc/Camera1Capturer.java",
+    "src/java/org/webrtc/Camera1Enumerator.java",
+    "src/java/org/webrtc/Camera1Session.java",
+    "src/java/org/webrtc/Camera2Capturer.java",
+    "src/java/org/webrtc/Camera2Enumerator.java",
+    "src/java/org/webrtc/Camera2Session.java",
+    "src/java/org/webrtc/CameraCapturer.java",
+    "src/java/org/webrtc/CameraEnumerationAndroid.java",
+    "src/java/org/webrtc/CameraEnumerator.java",
+    "src/java/org/webrtc/CameraSession.java",
+    "src/java/org/webrtc/CameraVideoCapturer.java",
+    "src/java/org/webrtc/DataChannel.java",
+    "src/java/org/webrtc/EglBase.java",
+    "src/java/org/webrtc/EglBase10.java",
+    "src/java/org/webrtc/EglBase14.java",
+    "src/java/org/webrtc/EglRenderer.java",
+    "src/java/org/webrtc/FileVideoCapturer.java",
+    "src/java/org/webrtc/GlRectDrawer.java",
+    "src/java/org/webrtc/GlShader.java",
+    "src/java/org/webrtc/GlTextureFrameBuffer.java",
+    "src/java/org/webrtc/GlUtil.java",
+    "src/java/org/webrtc/Histogram.java",
+    "src/java/org/webrtc/IceCandidate.java",
+    "src/java/org/webrtc/MediaCodecVideoDecoder.java",
+    "src/java/org/webrtc/MediaCodecVideoEncoder.java",
+    "src/java/org/webrtc/MediaConstraints.java",
+    "src/java/org/webrtc/MediaSource.java",
+    "src/java/org/webrtc/MediaStream.java",
+    "src/java/org/webrtc/MediaStreamTrack.java",
+    "src/java/org/webrtc/NetworkMonitor.java",
+    "src/java/org/webrtc/NetworkMonitorAutoDetect.java",
+    "src/java/org/webrtc/PeerConnection.java",
+    "src/java/org/webrtc/PeerConnectionFactory.java",
+    "src/java/org/webrtc/RendererCommon.java",
+    "src/java/org/webrtc/RtpParameters.java",
+    "src/java/org/webrtc/RtpReceiver.java",
+    "src/java/org/webrtc/RtpSender.java",
+    "src/java/org/webrtc/ScreenCapturerAndroid.java",
+    "src/java/org/webrtc/SdpObserver.java",
+    "src/java/org/webrtc/SessionDescription.java",
+    "src/java/org/webrtc/StatsObserver.java",
+    "src/java/org/webrtc/StatsReport.java",
+    "src/java/org/webrtc/SurfaceTextureHelper.java",
+    "src/java/org/webrtc/SurfaceViewRenderer.java",
+    "src/java/org/webrtc/VideoCapturer.java",
+    "src/java/org/webrtc/VideoCapturerAndroid.java",
+    "src/java/org/webrtc/VideoFileRenderer.java",
+    "src/java/org/webrtc/VideoRenderer.java",
+    "src/java/org/webrtc/VideoRendererGui.java",
+    "src/java/org/webrtc/VideoSource.java",
+    "src/java/org/webrtc/VideoTrack.java",
+    "src/java/org/webrtc/YuvConverter.java",
+  ]
+
+  deps = [
+    "//webrtc/base:base_java",
+  ]
+}
+
+android_library("libjingle_peerconnection_metrics_default_java") {
+  java_files = [ "src/java/org/webrtc/Metrics.java" ]
+
+  deps = [
+    "//webrtc/base:base_java",
+  ]
+}
+
+if (rtc_include_tests) {
+  instrumentation_test_apk("libjingle_peerconnection_android_unittest") {
+    apk_name = "libjingle_peerconnection_android_unittest"
+    android_manifest = "instrumentationtests/AndroidManifest.xml"
+
+    java_files = [
+      "instrumentationtests/src/org/webrtc/Camera1CapturerUsingByteBufferTest.java",
+      "instrumentationtests/src/org/webrtc/Camera1CapturerUsingTextureTest.java",
+      "instrumentationtests/src/org/webrtc/Camera2CapturerTest.java",
+      "instrumentationtests/src/org/webrtc/CameraVideoCapturerTestFixtures.java",
+      "instrumentationtests/src/org/webrtc/EglRendererTest.java",
+      "instrumentationtests/src/org/webrtc/GlRectDrawerTest.java",
+      "instrumentationtests/src/org/webrtc/MediaCodecVideoEncoderTest.java",
+      "instrumentationtests/src/org/webrtc/NetworkMonitorTest.java",
+      "instrumentationtests/src/org/webrtc/PeerConnectionTest.java",
+      "instrumentationtests/src/org/webrtc/RendererCommonTest.java",
+      "instrumentationtests/src/org/webrtc/SurfaceTextureHelperTest.java",
+      "instrumentationtests/src/org/webrtc/SurfaceViewRendererOnMeasureTest.java",
+      "instrumentationtests/src/org/webrtc/WebRtcJniBootTest.java",
+    ]
+
+    deps = [
+      "//base:base_java",
+      "//webrtc/base:base_java",
+      "//webrtc/sdk/android:libjingle_peerconnection_java",
+      "//webrtc/sdk/android:libjingle_peerconnection_metrics_default_java",
+    ]
+
+    shared_libraries = [ "//webrtc/sdk/android:libjingle_peerconnection_so" ]
+  }
+}