Create //webrtc/api:libjingle_peerconnection_api + refactorings.

webrtc/pc/BUILD.gn

 # Copyright (c) 2016 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../build/webrtc.gni")
+if (is_android) {
+  import("//build/config/android/config.gni")
+  import("//build/config/android/rules.gni")
+}
 
 group("pc") {
   public_deps = [
     ":rtc_pc",
   ]
 }
 
 config("rtc_pc_config") {
   defines = [
     "HAVE_SCTP",
@@ skipping 42 matching lines @@
   }
 
   public_configs = [ ":rtc_pc_config" ]
 
   if (!build_with_chromium && is_clang) {
     # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
     suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
   }
 }
 
+config("libjingle_peerconnection_warnings_config") {
+  # GN orders flags on a target before flags from configs. The default config
+  # adds these flags so to cancel them out they need to come from a config and
+  # cannot be on the target directly.
+  if (!is_win && !is_clang) {
+    cflags = [ "-Wno-maybe-uninitialized" ]  # Only exists for GCC.
+  }
+}
+
+rtc_static_library("libjingle_peerconnection") {
+  cflags = []
+  sources = [
+    "audiotrack.cc",
+    "audiotrack.h",
+    "datachannel.cc",
+    "datachannel.h",
+    "dtmfsender.cc",
+    "dtmfsender.h",
+    "jsepicecandidate.cc",
+    "jsepicecandidate.h",
+    "jsepsessiondescription.cc",
+    "jsepsessiondescription.h",
+    "localaudiosource.cc",
+    "localaudiosource.h",
+    "mediacontroller.cc",
+    "mediacontroller.h",
+    "mediastream.cc",
+    "mediastream.h",
+    "mediastreamobserver.cc",
+    "mediastreamobserver.h",
+    "mediastreamtrack.h",
+    "peerconnection.cc",
+    "peerconnection.h",
+    "peerconnectionfactory.cc",
+    "peerconnectionfactory.h",
+    "remoteaudiosource.cc",
+    "remoteaudiosource.h",
+    "rtcstatscollector.cc",
+    "rtcstatscollector.h",
+    "rtpreceiver.cc",
+    "rtpreceiver.h",
+    "rtpsender.cc",
+    "rtpsender.h",
+    "sctputils.cc",
+    "sctputils.h",
+    "statscollector.cc",
+    "statscollector.h",
+    "streamcollection.h",
+    "videocapturertracksource.cc",
+    "videocapturertracksource.h",
+    "videotrack.cc",
+    "videotrack.h",
+    "videotracksource.cc",
+    "videotracksource.h",
+    "webrtcsdp.cc",
+    "webrtcsdp.h",
+    "webrtcsession.cc",
+    "webrtcsession.h",
+    "webrtcsessiondescriptionfactory.cc",
+    "webrtcsessiondescriptionfactory.h",
+  ]
+
+  configs += [ ":libjingle_peerconnection_warnings_config" ]
+
+  if (!build_with_chromium && is_clang) {
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+    suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+  }
+
+  deps = [
+    ":rtc_pc",
+    "../api:call_api",
+    "../api:libjingle_peerconnection_api",
+    "../api:rtc_stats_api",
+    "../call",
+    "../media",
+    "../stats",
+  ]
+
+  if (rtc_use_quic) {
+    sources += [
+      "quicdatachannel.cc",
+      "quicdatachannel.h",
+      "quicdatatransport.cc",
+      "quicdatatransport.h",
+    ]
+    deps += [ "//third_party/libquic" ]
+    public_deps = [
+      "//third_party/libquic",
+    ]
+  }
+}
+
 if (rtc_include_tests) {
   config("rtc_pc_unittests_config") {
     # GN orders flags on a target before flags from configs. The default config
     # adds -Wall, and this flag have to be after -Wall -- so they need to
     # come from a config and can't be on the target directly.
     if (!is_win && !is_clang) {
       cflags = [ "-Wno-maybe-uninitialized" ]  # Only exists for GCC.
     }
   }
 
@@ skipping 17 matching lines @@
     if (!build_with_chromium && is_clang) {
       # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
       suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
     }
 
     if (is_win) {
       libs = [ "strmiids.lib" ]
     }
 
     deps = [
+      ":libjingle_peerconnection",
       ":rtc_pc",
-      "../api:libjingle_peerconnection",
       "../base:rtc_base_tests_utils",
       "../media:rtc_unittest_main",
       "../system_wrappers:metrics_default",
     ]
 
     if (rtc_build_libsrtp) {
       deps += [ "//third_party/libsrtp" ]
     }
 
     if (is_android) {
       deps += [ "//testing/android/native_test:native_test_support" ]
     }
   }
+
+  config("peerconnection_unittests_config") {
+    # The warnings below are enabled by default. Since GN orders compiler flags
+    # for a target before flags from configs, the only way to disable such
+    # warnings is by having them in a separate config, loaded from the target.
+    # TODO(kjellander): Make the code compile without disabling these flags.
+    # See https://bugs.webrtc.org/3307.
+    if (is_clang && is_win) {
+      cflags = [
+        # See https://bugs.chromium.org/p/webrtc/issues/detail?id=6267
+        # for -Wno-sign-compare
+        "-Wno-sign-compare",
+        "-Wno-unused-function",
+      ]
+    }
+
+    if (!is_win) {
+      cflags = [ "-Wno-sign-compare" ]
+    }
+  }
+
+  rtc_test("peerconnection_unittests") {
+    testonly = true
+    sources = [
+      "datachannel_unittest.cc",
+      "dtmfsender_unittest.cc",
+      "fakemediacontroller.h",
+      "jsepsessiondescription_unittest.cc",
+      "localaudiosource_unittest.cc",
+      "mediaconstraintsinterface_unittest.cc",
+      "mediastream_unittest.cc",
+      "peerconnection_unittest.cc",
+      "peerconnectionendtoend_unittest.cc",
+      "peerconnectionfactory_unittest.cc",
+      "peerconnectioninterface_unittest.cc",
+      "proxy_unittest.cc",
+      "rtcstatscollector_unittest.cc",
+      "rtpsenderreceiver_unittest.cc",
+      "sctputils_unittest.cc",
+      "statscollector_unittest.cc",
+      "test/fakeaudiocapturemodule.cc",
+      "test/fakeaudiocapturemodule.h",
+      "test/fakeaudiocapturemodule_unittest.cc",
+      "test/fakeconstraints.h",
+      "test/fakedatachannelprovider.h",
+      "test/fakeperiodicvideocapturer.h",
+      "test/fakertccertificategenerator.h",
+      "test/fakevideotrackrenderer.h",
+      "test/fakevideotracksource.h",
+      "test/mock_datachannel.h",
+      "test/mock_peerconnection.h",
+      "test/mock_webrtcsession.h",
+      "test/mockpeerconnectionobservers.h",
+      "test/peerconnectiontestwrapper.cc",
+      "test/peerconnectiontestwrapper.h",
+      "test/testsdpstrings.h",
+      "videocapturertracksource_unittest.cc",
+      "videotrack_unittest.cc",
+      "webrtcsdp_unittest.cc",
+      "webrtcsession_unittest.cc",
+    ]
+
+    defines = [ "HAVE_SCTP" ]
+
+    configs += [ ":peerconnection_unittests_config" ]
+
+    if (!build_with_chromium && is_clang) {
+      # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+      suppressed_configs += [ "//build/config/clang:find_bad_constructs" ]
+    }
+
+    # TODO(jschuh): Bug 1348: fix this warning.
+    configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
+
+    if (is_win) {
+      cflags = [
+        "/wd4245",  # conversion from int to size_t, signed/unsigned mismatch.
+        "/wd4389",  # signed/unsigned mismatch.
+      ]
+    }
+
+    if (rtc_use_quic) {
+      public_deps = [
+        "//third_party/libquic",
+      ]
+      sources += [
+        "quicdatachannel_unittest.cc",
+        "quicdatatransport_unittest.cc",
+      ]
+    }
+
+    deps = []
+    if (is_android) {
+      sources += [
+        "test/androidtestinitializer.cc",
+        "test/androidtestinitializer.h",
+      ]
+      deps += [
+        "../api:libjingle_peerconnection_java",
+        "../api:libjingle_peerconnection_jni",
+        "//testing/android/native_test:native_test_support",
+      ]
+    }
+
+    deps += [
+      ":libjingle_peerconnection",
+      "..:webrtc_common",
+      "../base:rtc_base_tests_utils",
+      "../media:rtc_unittest_main",
+      "../pc:rtc_pc",
+      "../system_wrappers:metrics_default",
+      "//testing/gmock",
+    ]
+
+    if (is_android) {
+      deps += [ "//testing/android/native_test:native_test_support" ]
+
+      shard_timeout = 900
+    }
+  }
+
+  if (is_android) {
+    instrumentation_test_apk("libjingle_peerconnection_android_unittest") {
+      apk_name = "libjingle_peerconnection_android_unittest"
+      android_manifest = "androidtests/AndroidManifest.xml"
+
+      java_files = [
+        "androidtests/src/org/webrtc/Camera1CapturerUsingByteBufferTest.java",
+        "androidtests/src/org/webrtc/Camera1CapturerUsingTextureTest.java",
+        "androidtests/src/org/webrtc/Camera2CapturerTest.java",
+        "androidtests/src/org/webrtc/CameraVideoCapturerTestFixtures.java",
+        "androidtests/src/org/webrtc/EglRendererTest.java",
+        "androidtests/src/org/webrtc/GlRectDrawerTest.java",
+        "androidtests/src/org/webrtc/MediaCodecVideoEncoderTest.java",
+        "androidtests/src/org/webrtc/NetworkMonitorTest.java",
+        "androidtests/src/org/webrtc/PeerConnectionTest.java",
+        "androidtests/src/org/webrtc/RendererCommonTest.java",
+        "androidtests/src/org/webrtc/SurfaceTextureHelperTest.java",
+        "androidtests/src/org/webrtc/SurfaceViewRendererOnMeasureTest.java",
+        "androidtests/src/org/webrtc/WebRtcJniBootTest.java",
+      ]
+
+      deps = [
+        "../api:libjingle_peerconnection_java",
+        "../base:base_java",
+        "//base:base_java",
+      ]
+
+      shared_libraries = [ "../api:libjingle_peerconnection_so" ]
+    }
+  }
 }