Add the OnAddTrack callback for Objective-C wrapper.

webrtc/sdk/objc/Framework/Classes/RTCPeerConnection.mm

 /*
  *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
  *
  *  Use of this source code is governed by a BSD-style license
  *  that can be found in the LICENSE file in the root of the source
  *  tree. An additional intellectual property rights grant can be found
  *  in the file PATENTS.  All contributing project authors may
  *  be found in the AUTHORS file in the root of the source tree.
  */
 
 #import "RTCPeerConnection+Private.h"
 
 #import "NSString+StdString.h"
 #import "RTCConfiguration+Private.h"
 #import "RTCDataChannel+Private.h"
 #import "RTCIceCandidate+Private.h"
 #import "RTCLegacyStatsReport+Private.h"
 #import "RTCMediaConstraints+Private.h"
 #import "RTCMediaStream+Private.h"
 #import "RTCPeerConnectionFactory+Private.h"
 #import "RTCRtpReceiver+Private.h"
 #import "RTCRtpSender+Private.h"
 #import "RTCSessionDescription+Private.h"
 #import "WebRTC/RTCLogging.h"
 
 #include <memory>
 
 #include "webrtc/api/jsepicecandidate.h"
 #include "webrtc/base/checks.h"
+#include "webrtc/sdk/objc/Framework/Classes/helpers.h"

[tkchin_webrtc, 2017/02/24 20:54:15]

you don't need this include, NSString+StdString has what you need already

 
 NSString * const kRTCPeerConnectionErrorDomain =
     @"org.webrtc.RTCPeerConnection";
 int const kRTCPeerConnnectionSessionDescriptionError = -1;
 
 namespace webrtc {
 
 class CreateSessionDescriptionObserverAdapter
     : public CreateSessionDescriptionObserver {
  public:
@@ skipping 80 matching lines @@
     PeerConnectionInterface::SignalingState new_state) {
   RTCSignalingState state =
       [[RTCPeerConnection class] signalingStateForNativeState:new_state];
   RTCPeerConnection *peer_connection = peer_connection_;
   [peer_connection.delegate peerConnection:peer_connection
                    didChangeSignalingState:state];
 }
 
 void PeerConnectionDelegateAdapter::OnAddStream(
     rtc::scoped_refptr<MediaStreamInterface> stream) {
-  RTCMediaStream *mediaStream =
-      [[RTCMediaStream alloc] initWithNativeMediaStream:stream];
   RTCPeerConnection *peer_connection = peer_connection_;
+  RTCMediaStream *mediaStream = [peer_connection mediaStreamForNativeStream:stream];
   [peer_connection.delegate peerConnection:peer_connection
                               didAddStream:mediaStream];
 }
 
 void PeerConnectionDelegateAdapter::OnRemoveStream(
     rtc::scoped_refptr<MediaStreamInterface> stream) {
   RTCMediaStream *mediaStream =
       [[RTCMediaStream alloc] initWithNativeMediaStream:stream];
   RTCPeerConnection *peer_connection = peer_connection_;
   [peer_connection.delegate peerConnection:peer_connection
                            didRemoveStream:mediaStream];
+  [peer_connection removeNativeMediaStream:stream];
 }
 
 void PeerConnectionDelegateAdapter::OnDataChannel(
     rtc::scoped_refptr<DataChannelInterface> data_channel) {
   RTCDataChannel *dataChannel =
       [[RTCDataChannel alloc] initWithNativeDataChannel:data_channel];
   RTCPeerConnection *peer_connection = peer_connection_;
   [peer_connection.delegate peerConnection:peer_connection
                         didOpenDataChannel:dataChannel];
 }
@@ skipping 39 matching lines @@
         new JsepIceCandidate(candidate.transport_name(), -1, candidate));
     RTCIceCandidate* ice_candidate = [[RTCIceCandidate alloc]
         initWithNativeCandidate:candidate_wrapper.get()];
     [ice_candidates addObject:ice_candidate];
   }
   RTCPeerConnection* peer_connection = peer_connection_;
   [peer_connection.delegate peerConnection:peer_connection
                     didRemoveIceCandidates:ice_candidates];
 }
 
+void PeerConnectionDelegateAdapter::OnAddTrack(
+    rtc::scoped_refptr<RtpReceiverInterface> receiver,
+    const std::vector<rtc::scoped_refptr<MediaStreamInterface>>& streams) {
+  RTCRtpReceiver* rtpReceiver =
+      [[RTCRtpReceiver alloc] initWithNativeRtpReceiver:receiver];
+  NSMutableArray* mediaStreams =
+      [NSMutableArray arrayWithCapacity:streams.size()];
+
+  RTCPeerConnection* peer_connection = peer_connection_;
+  for (const auto stream : streams) {
+    RTCMediaStream* mediaStream =
+        [peer_connection mediaStreamForNativeStream:stream];
+    [mediaStreams addObject:mediaStream];
+  }
+  if ([peer_connection.delegate
+      respondsToSelector:@selector(peerConnection:didAddTrack:streams:)]) {
+    [peer_connection.delegate peerConnection:peer_connection
+                                 didAddTrack:rtpReceiver
+                                     streams:mediaStreams];
+  }
+}
+
 }  // namespace webrtc
 
 
 @implementation RTCPeerConnection {
   NSMutableArray<RTCMediaStream *> *_localStreams;
   std::unique_ptr<webrtc::PeerConnectionDelegateAdapter> _observer;
   rtc::scoped_refptr<webrtc::PeerConnectionInterface> _peerConnection;
   std::unique_ptr<webrtc::MediaConstraints> _nativeConstraints;
   BOOL _hasStartedRtcEventLog;
+  NSMutableDictionary<NSString *, RTCMediaStream *> *_mediaStreamsByStreamId;
 }
 
 @synthesize delegate = _delegate;
 
 - (instancetype)initWithFactory:(RTCPeerConnectionFactory *)factory
                   configuration:(RTCConfiguration *)configuration
                     constraints:(RTCMediaConstraints *)constraints
                        delegate:(id<RTCPeerConnectionDelegate>)delegate {
   NSParameterAssert(factory);
   std::unique_ptr<webrtc::PeerConnectionInterface::RTCConfiguration> config(
       [configuration createNativeConfiguration]);
   if (!config) {
     return nil;
   }
   if (self = [super init]) {
     _observer.reset(new webrtc::PeerConnectionDelegateAdapter(self));
     _nativeConstraints = constraints.nativeConstraints;
     CopyConstraintsIntoRtcConfiguration(_nativeConstraints.get(),
                                         config.get());
     _peerConnection =
         factory.nativeFactory->CreatePeerConnection(*config,
                                                     nullptr,
                                                     nullptr,
                                                     _observer.get());
     if (!_peerConnection) {
       return nil;
     }
     _localStreams = [[NSMutableArray alloc] init];
     _delegate = delegate;
+    _mediaStreamsByStreamId = [NSMutableDictionary dictionary];
   }
   return self;
 }
 
 - (NSArray<RTCMediaStream *> *)localStreams {
   return [_localStreams copy];
 }
 
 - (RTCSessionDescription *)localDescription {
   const webrtc::SessionDescriptionInterface *description =
@@ skipping 330 matching lines @@
 + (webrtc::PeerConnectionInterface::StatsOutputLevel)
     nativeStatsOutputLevelForLevel:(RTCStatsOutputLevel)level {
   switch (level) {
     case RTCStatsOutputLevelStandard:
       return webrtc::PeerConnectionInterface::kStatsOutputLevelStandard;
     case RTCStatsOutputLevelDebug:
       return webrtc::PeerConnectionInterface::kStatsOutputLevelDebug;
   }
 }
 
+- (RTCMediaStream *)mediaStreamForNativeStream:
+    (rtc::scoped_refptr<webrtc::MediaStreamInterface>)stream {
+  RTCMediaStream *mediaStream =
+      _mediaStreamsByStreamId[[NSString stringForStdString:stream->label()]];

[tkchin_webrtc, 2017/02/24 20:54:15]

nit: pull this out into a local so you're not creating multiple strings each
time

+  if (!mediaStream) {
+    mediaStream = [[RTCMediaStream alloc] initWithNativeMediaStream:stream.get()];
+    _mediaStreamsByStreamId[[NSString stringForStdString:stream->label()]] = mediaStream;
+  }
+  return mediaStream;
+}
+
+- (void)removeNativeMediaStream:(rtc::scoped_refptr<webrtc::MediaStreamInterface>)stream {
+  [_mediaStreamsByStreamId removeObjectForKey:[NSString stringForStdString:stream->label()]];
+}
+
 - (rtc::scoped_refptr<webrtc::PeerConnectionInterface>)nativePeerConnection {
   return _peerConnection;
 }
 
 @end