Split audio mixer into interface and implementation.

webrtc/modules/audio_mixer/BUILD.gn

 # Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../../build/webrtc.gni")
 
-config("audio_conference_mixer_config") {
-  include_dirs = [ "../../modules/include" ]
-}
-
-rtc_static_library("audio_mixer") {
+rtc_static_library("audio_mixer_impl") {
+  visibility = [
+    "../../audio:audio",
+    "../../modules/*",
+  ]
   sources = [
-    "audio_frame_manipulator.cc",
-    "audio_frame_manipulator.h",
-    "audio_mixer.h",
     "audio_mixer_impl.cc",
     "audio_mixer_impl.h",
     "audio_source_with_mix_status.cc",
     "audio_source_with_mix_status.h",
   ]
 
   public = [
-    "audio_mixer.h",
+    "audio_mixer_impl.h",
   ]
 
-  public_configs = [ ":audio_conference_mixer_config" ]
+  public_deps = [
+    "../../api:audio_mixer_api",
+  ]

[aleloi, 2016/10/13 09:25:23]

This way, targets that create the mixer and include the api do not need to
explicitly depend on it. Our situation seems to fit one of the cases described
in "gn help public_deps":

  Generally if you are writing a target B and you include C's headers
  as part of B's public headers, or targets depending on B should
  consider B and C to be part of a unit, you should use public_deps
  instead of deps.

(with B=audio_mixer_impl and C=audio_mixer_api)

 
   deps = [
+    ":audio_frame_manipulator",
     "../..:webrtc_common",
     "../../base:rtc_base_approved",
     "../../modules/audio_processing",
     "../../modules/utility",
     "../../system_wrappers",
-    "../../voice_engine:level_indicator",
   ]
 }
+
+rtc_static_library("audio_frame_manipulator") {
+  visibility = [
+    ":*",
+    "../../modules:modules_unittests",
+  ]
+
+  sources = [
+    "audio_frame_manipulator.cc",
+    "audio_frame_manipulator.h",
+  ]
+
+  deps = [
+    "../../base:rtc_base_approved",
+    "../../modules/utility",
+  ]
+}

[aleloi, 2016/10/13 09:25:23]

The mixer directory contains a test file called
audio_frame_manipulator_unittests.cc, which is part of the target
modules:modules_unittests. The unit test includes audio_frame_manipulator.h,
which was forbidden by GN's include header checker. It was forbidden, because
:audio_mixer_impl only declared audio_mixer_impl.h to be a public header.