GN Templates: Move common_inherited_config to the template.

webrtc/build/webrtc.gni

 # Copyright (c) 2014 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("//build/config/arm.gni")
 import("//build/config/features.gni")
@@ skipping 144 matching lines @@
 # Templates
 #
 
 # Points to //webrtc/ in webrtc stand-alone or to //third_party/webrtc/ in
 # chromium.
 # We need absolute paths for all configs in templates as they are shared in
 # different subdirectories.
 webrtc_root = get_path_info("../", "abspath")
 
 # Global configuration that should be applied to all WebRTC targets.
-# You normally shouldn't need to # include this in your target as it's
+# You normally shouldn't need to include this in your target as it's
 # automatically included when using the rtc_* templates.
 # It sets defines, include paths and compilation warnings accordingly,
 # both for WebRTC stand-alone builds and for the scenario when WebRTC
 # native code is built as part of Chromium.
 rtc_common_config = webrtc_root + ":common_config"
+rtc_common_inherited_config = webrtc_root + ":common_inherited_config"

[kjellander_webrtc, 2016/09/05 12:41:31]

Add a separate comment about this one:

Global public configuration that should be applied to all WebRTC targets. You
normally shouldn't need to include this in your target as it's automatically
included when using the rtc_* templates. It set the defines, include paths and
compilation warnings that should be propagated to dependents of the targets
depending on the target having this config.

[ehmaldonado_webrtc, 2016/09/05 12:49:59]

Done.

 
 # Common configs to remove or add in all rtc targets.
 rtc_remove_configs = []
 rtc_add_configs = [ rtc_common_config ]
 
 if (!is_debug) {
   rtc_remove_configs += [ "//build/config/compiler:default_optimization" ]
   rtc_add_configs += [ "//build/config/compiler:optimize_max" ]
 }
 
@@ skipping 16 matching lines @@
   configs = rtc_add_configs
   suppressed_configs = []
 }
 
 template("rtc_test") {
   test(target_name) {
     forward_variables_from(invoker,
                            "*",
                            [
                              "configs",
+                             "public_configs",
                              "suppressed_configs",
                            ])
     configs += invoker.configs
     configs -= rtc_remove_configs
     configs -= invoker.suppressed_configs
+    public_configs = [ rtc_common_inherited_config ]
+    if (defined(invoker.public_configs)) {

[kjellander_webrtc, 2016/09/05 12:41:31]

I guess this check is needed because public_configs is normally not set, while
that's not the case for configs (which I guess always has something by default
in GN?).

[ehmaldonado_webrtc, 2016/09/05 12:49:59]

Yes, the default configs is defined in BUILDCONFIG.gn
https://cs.chromium.org/chromium/src/build/config/BUILDCONFIG.gn?l=522

Another approach would be to set as a default public_configs = [] for our
templates, and skip the test here.

+      public_configs += invoker.public_configs
+    }
   }
 }
 
 template("rtc_source_set") {
   source_set(target_name) {
     forward_variables_from(invoker,
                            "*",
                            [
                              "configs",
+                             "public_configs",
                              "suppressed_configs",
                            ])
     configs += invoker.configs
     configs -= rtc_remove_configs
     configs -= invoker.suppressed_configs
+    public_configs = [ rtc_common_inherited_config ]
+    if (defined(invoker.public_configs)) {
+      public_configs += invoker.public_configs
+    }
   }
 }
 
 template("rtc_executable") {
   executable(target_name) {
     forward_variables_from(invoker,
                            "*",
                            [
                              "deps",
                              "configs",
+                             "public_configs",
                              "suppressed_configs",
                            ])
     configs += invoker.configs
     configs -= rtc_remove_configs
     configs -= invoker.suppressed_configs
     deps = [
       "//build/config/sanitizers:deps",
     ]
     deps += invoker.deps
+    public_configs = [ rtc_common_inherited_config ]
+    if (defined(invoker.public_configs)) {
+      public_configs += invoker.public_configs
+    }
   }
 }
 
 template("rtc_static_library") {
   static_library(target_name) {
     forward_variables_from(invoker,
                            "*",
                            [
                              "configs",
+                             "public_configs",
                              "suppressed_configs",
                            ])
     configs += invoker.configs
     configs -= rtc_remove_configs
     configs -= invoker.suppressed_configs
+    public_configs = [ rtc_common_inherited_config ]
+    if (defined(invoker.public_configs)) {
+      public_configs += invoker.public_configs
+    }
   }
 }