Add libjingle_peerconnection_unittest to GN targets.

webrtc/api/BUILD.gn

 # Copyright (c) 2015 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../build/webrtc.gni")
 import("//testing/test.gni")
@@ skipping 381 matching lines @@
       "../media:rtc_unittest_main",
       "../pc:rtc_pc",
       "../system_wrappers:metrics_default",
       "//testing/gmock",
     ]
 
     if (is_android) {
       deps += [ "//testing/android/native_test:native_test_support" ]
     }
   }
+
+  if (is_android) {
+    android_apk("libjingle_peerconnection_android_unittest_apk") {

[sakal, 2016/08/10 07:56:57]

This target is not needed. There is no application apk. Please remove.

+      apk_name = "libjingle_peerconnection_android"
+      android_manifest = "androidtests/AndroidManifest.xml"
+
+      deps = [
+        ":libjingle_peerconnection_android_unittest_java",
+        ":libjingle_peerconnection_android_unittest_resources",
+        "//base:base_java",
+        "//webrtc/base:base_java",
+      ]
+
+      shared_libraries = [ ":libjingle_peerconnection_so" ]
+    }
+
+    android_library("libjingle_peerconnection_android_unittest_java") {

[sakal, 2016/08/10 07:56:57]

This is not needed either. I created it for AppRTCDemo so I can share code
between the application apk and the test apk. Move java files directly to
libjingle_peerconnection_android_unittest.

+      java_files = [
+        "androidtests/src/org/webrtc/Camera1CapturerUsingByteBufferTest.java",
+        "androidtests/src/org/webrtc/Camera1CapturerUsingTextureTest.java",
+        "androidtests/src/org/webrtc/Camera2CapturerTest.java",
+        "androidtests/src/org/webrtc/CameraVideoCapturerTestFixtures.java",
+        "androidtests/src/org/webrtc/GlRectDrawerTest.java",
+        "androidtests/src/org/webrtc/MediaCodecVideoEncoderTest.java",
+        "androidtests/src/org/webrtc/NetworkMonitorTest.java",
+        "androidtests/src/org/webrtc/RendererCommonTest.java",
+        "androidtests/src/org/webrtc/SurfaceTextureHelperTest.java",
+        "androidtests/src/org/webrtc/SurfaceViewRendererOnMeasureTest.java",
+      ]
+
+      deps = [
+        ":libjingle_peerconnection_android_unittest_resources",
+        ":libjingle_peerconnection_java",
+        "//webrtc/base:base_java",
+      ]
+    }
+
+    android_resources("libjingle_peerconnection_android_unittest_resources") {

[sakal, 2016/08/10 07:56:57]

I would move this target below libjingle_peerconnection_android_unittest. From
the style guide:
Other targets should be in “some order that makes sense.” Usually more important
targets will be first, and unit tests will follow the corresponding target. If
there's no clear ordering, consider alphabetical order.

+      resource_dirs = [ "androidtests/res" ]
+      custom_package = "org.webrtc"

[sakal, 2016/08/10 07:56:57]

This should be "org.webrtc.test". Resources are for the test apk directly.

+    }
+
+    instrumentation_test_apk("libjingle_peerconnection_android_unittest") {
+      apk_name = "libjingle_peerconnection_android_unittest"
+      android_manifest = "androidtests/AndroidManifest.xml"
+
+      java_files = [ "androidtests/src/org/webrtc/PeerConnectionTest.java" ]

[sakal, 2016/08/10 07:56:57]

Add rest of the java files here.

+
+      apk_under_test = ":libjingle_peerconnection_android_unittest_apk"

[sakal, 2016/08/10 07:56:57]

This target does not test an apk. Please remove this line.

+
+      deps = [
+        ":libjingle_peerconnection_android_unittest_java",

[sakal, 2016/08/10 07:56:57]

Remove this dependency and add "//base:base_java", "//webrtc/base:base_java" and
":libjingle_peerconnection_android_unittest_resources".

+        ":libjingle_peerconnection_java",
+      ]

[sakal, 2016/08/10 07:56:57]

Add: shared_libraries = [ ":libjingle_peerconnection_so" ]

+    }
+  }
 }