GN: Add target for modules_tests.

webrtc/modules/BUILD.gn

 # Copyright (c) 2016 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../build/webrtc.gni")
 import("audio_coding/audio_coding.gni")
+import("video_coding/video_coding.gni")
 import("//testing/test.gni")
 
 declare_args() {
   # Desktop capturer is supported only on Windows, OSX and Linux.
   rtc_desktop_capture_supported = is_win || is_mac || is_linux
 }
 
 group("modules") {
   deps = [
     "audio_coding",
     "audio_conference_mixer",
     "audio_device",
     "audio_mixer",
     "audio_processing",
     "bitrate_controller",
     "desktop_capture",
     "media_file",
     "rtp_rtcp",
     "utility",
     "video_coding",
     "video_processing",
   ]
 }
 
 if (rtc_include_tests) {
+  test("modules_tests") {
+    testonly = true
+
+    configs += [ "..:common_config" ]
+    public_configs = [ "..:common_inherited_config" ]
+
+    defines = audio_coding_defines + videoprocessor_defines
+
+    deps = [
+      "..:webrtc_common",
+      "../common_video",
+      "../modules/audio_coding",
+      "../modules/rtp_rtcp",
+      "../modules/utility",
+      "../modules/video_coding",
+      "../modules/video_coding:video_codecs_test_framework",
+      "../system_wrappers",
+      "../test:test_support",
+      "../test:test_support_main",
+      "//testing/gtest",
+    ]
+
+    sources = [
+      "audio_coding/test/APITest.cc",
+      "audio_coding/test/Channel.cc",
+      "audio_coding/test/EncodeDecodeTest.cc",
+      "audio_coding/test/PCMFile.cc",
+      "audio_coding/test/PacketLossTest.cc",
+      "audio_coding/test/RTPFile.cc",
+      "audio_coding/test/TestAllCodecs.cc",
+      "audio_coding/test/TestRedFec.cc",
+      "audio_coding/test/TestStereo.cc",
+      "audio_coding/test/TestVADDTX.cc",
+      "audio_coding/test/Tester.cc",
+      "audio_coding/test/TwoWayCommunication.cc",
+      "audio_coding/test/iSACTest.cc",
+      "audio_coding/test/opus_test.cc",
+      "audio_coding/test/target_delay_unittest.cc",
+      "audio_coding/test/utility.cc",
+      "rtp_rtcp/test/testFec/test_fec.cc",
+      "video_coding/codecs/test/videoprocessor_integrationtest.cc",
+      "video_coding/codecs/vp8/test/vp8_impl_unittest.cc",
+    ]
+
+    if (is_android) {
+      deps += [ "//testing/android/native_test:native_test_native_code" ]
+    }
+    if (is_ios) {

[kjellander_webrtc, 2016/08/03 15:22:49]

Make this 
if (is_android || is_ios) {
instead. I think there are some errors in other tests as well regarding this (we
only run a few tests on iOS so that's probably why it's not been detected). Also
the GN trybots don't run the Android tests yet, since we have limited machines
with Android devices. I was planning on going through the Android tests once we
got everything else in place.

[ehmaldonado_webrtc, 2016/08/03 15:40:43]

Done.

+      data = [
+        "//resources/audio_coding/testfile32kHz.pcm",
+        "//resources/audio_coding/teststereo32kHz.pcm",
+        "//resources/foreman_cif.yuv",
+        "//resources/paris_qcif.yuv",
+      ]
+    }
+
+    if (is_clang) {
+      # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+      configs -= [ "//build/config/clang:find_bad_constructs" ]
+    }
+    if (is_win) {
+      cflags = [
+        # TODO(phoglund): get rid of 4373 supression when
+        # http://code.google.com/p/webrtc/issues/detail?id=261 is solved.
+        # legacy warning for ignoring const / volatile in signatures.
+        "/wd4373",
+      ]
+    }
+  }
+
   test("modules_unittests") {
     testonly = true
 
     defines = audio_coding_defines
     deps = []
     sources = [
       "audio_coding/acm2/acm_receiver_unittest_oldapi.cc",
       "audio_coding/acm2/audio_coding_module_unittest_oldapi.cc",
       "audio_coding/acm2/call_statistics_unittest.cc",
       "audio_coding/acm2/codec_manager_unittest.cc",
@@ skipping 489 matching lines @@
         "audio_device/ios/objc/RTCAudioSessionTest.mm",
         "video_coding/codecs/h264/h264_video_toolbox_nalu_unittest.cc",
       ]
 
       ldflags = [ "-ObjC" ]
 
       # TODO(kjellander): Mac bundle files.
     }
   }
 }