GN: Add peerconnection_unittests

webrtc/api/BUILD.gn

 # Copyright (c) 2015 The WebRTC project authors. All Rights Reserved.
 #
 # Use of this source code is governed by a BSD-style license
 # that can be found in the LICENSE file in the root of the source
 # tree. An additional intellectual property rights grant can be found
 # in the file PATENTS.  All contributing project authors may
 # be found in the AUTHORS file in the root of the source tree.
 
 import("../build/webrtc.gni")
+import("//testing/test.gni")
 
 group("api") {
   deps = [
     ":libjingle_peerconnection",
   ]
 }
 
 config("libjingle_peerconnection_warnings_config") {
   # GN orders flags on a target before flags from configs. The default config
   # adds these flags so to cancel them out they need to come from a config and
@@ skipping 78 matching lines @@
     "webrtcsessiondescriptionfactory.h",
   ]
 
   configs += [
     "..:common_config",
     ":libjingle_peerconnection_warnings_config",
   ]
   public_configs = [ "..:common_inherited_config" ]
 
   if (is_clang) {
-    # Suppress warnings from Chrome's Clang plugins.
-    # See http://code.google.com/p/webrtc/issues/detail?id=163 for details.
-    configs -= [ "//build/config/clang:extra_warnings" ]
+    # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
     configs -= [ "//build/config/clang:find_bad_constructs" ]
   }
 
   if (is_win) {
     cflags += [ "/wd4389" ]  # signed/unsigned mismatch.
   }
 
   deps = [
     "../call",
     "../media",
     "../pc",
   ]
 
   if (rtc_use_quic) {
     sources += [
       "quicdatachannel.cc",
       "quicdatachannel.h",
       "quicdatatransport.cc",
       "quicdatatransport.h",
     ]
     deps += [ "//third_party/libquic" ]
     public_deps = [
       "//third_party/libquic",
     ]
   }
 }
+
+if (is_android) {
+  config("libjingle_peerconnection_jni_warnings_config") {
+    # GN orders flags on a target before flags from configs. The default config
+    # adds these flags so to cancel them out they need to come from a config and

[perkj_webrtc, 2016/06/13 14:57:03]

Can this sentence be rephrased a bit. I am having trouble understanding what it
means.

[kjellander_webrtc, 2016/06/13 18:41:23]

Done.

+    # cannot be on the target directly.
+    if (!is_win) {
+      cflags = [
+        "-Wno-sign-compare",
+        "-Wno-unused-variable",
+      ]
+    }
+  }
+
+  source_set("libjingle_peerconnection_jni") {
+    sources = [
+      "androidvideocapturer.cc",
+      "androidvideocapturer.h",
+      "java/jni/androidmediacodeccommon.h",
+      "java/jni/androidmediadecoder_jni.cc",
+      "java/jni/androidmediadecoder_jni.h",
+      "java/jni/androidmediaencoder_jni.cc",
+      "java/jni/androidmediaencoder_jni.h",
+      "java/jni/androidmetrics_jni.cc",
+      "java/jni/androidnetworkmonitor_jni.cc",
+      "java/jni/androidnetworkmonitor_jni.h",
+      "java/jni/androidvideocapturer_jni.cc",
+      "java/jni/androidvideocapturer_jni.h",
+      "java/jni/classreferenceholder.cc",
+      "java/jni/classreferenceholder.h",
+      "java/jni/jni_helpers.cc",
+      "java/jni/jni_helpers.h",
+      "java/jni/native_handle_impl.cc",
+      "java/jni/native_handle_impl.h",
+      "java/jni/peerconnection_jni.cc",
+      "java/jni/surfacetexturehelper_jni.cc",
+      "java/jni/surfacetexturehelper_jni.h",
+    ]
+
+    configs += [
+      "..:common_config",
+      ":libjingle_peerconnection_jni_warnings_config",
+    ]
+    public_configs = [ "..:common_inherited_config" ]
+
+    if (is_clang) {
+      # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+      configs -= [
+        "//build/config/clang:extra_warnings",
+        "//build/config/clang:find_bad_constructs",
+      ]
+    }
+
+    # TODO(jschuh): Bug 1348: fix this warning.
+    configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
+
+    if (is_win) {
+      cflags += [
+        "/wd4245",  # conversion from "int" to "size_t", signed/unsigned mismatch.
+        "/wd4389",  # signed/unsigned mismatch.
+      ]
+    }
+
+    deps = [
+      ":libjingle_peerconnection",
+      "../system_wrappers:field_trial_default",
+      "../system_wrappers:metrics_default",
+    ]
+
+    if (rtc_build_libyuv) {
+      deps += [ "$rtc_libyuv_dir" ]
+      public_deps = [
+        "$rtc_libyuv_dir",
+      ]
+    } else {
+      # Need to add a directory normally exported by libyuv.
+      include_dirs += [ "$rtc_libyuv_dir/include" ]
+    }
+  }
+}
+
+if (rtc_include_tests) {
+  config("peerconnection_unittests_config") {
+    # GN orders flags on a target before flags from configs. The default config
+    # adds -Wall, and this flag have to be after -Wall -- so they need to

[perkj_webrtc, 2016/06/13 14:57:03]

this/ these? .. this flag have to be after -- so they need... ? 

[kjellander_webrtc, 2016/06/13 18:41:23]

You're right, I clarified this and the above.

+    # come from a config and can"t be on the target directly.
+    # TODO(kjellander): Make the code compile without disabling these flags.
+    # See https://bugs.webrtc.org/3307.
+    if (is_clang && is_win) {
+      cflags = [ "-Wno-unused-function" ]
+    }
+
+    if (!is_win) {
+      cflags = [ "-Wno-sign-compare" ]
+      cflags_cc = [ "-Wno-overloaded-virtual" ]
+    }
+  }
+
+  test("peerconnection_unittests") {
+    testonly = true
+    sources = [
+      "datachannel_unittest.cc",
+      "dtmfsender_unittest.cc",
+      "fakemetricsobserver.cc",
+      "fakemetricsobserver.h",
+      "jsepsessiondescription_unittest.cc",
+      "localaudiosource_unittest.cc",
+      "mediaconstraintsinterface_unittest.cc",
+      "mediastream_unittest.cc",
+      "peerconnection_unittest.cc",
+      "peerconnectionendtoend_unittest.cc",
+      "peerconnectionfactory_unittest.cc",
+      "peerconnectioninterface_unittest.cc",
+      "proxy_unittest.cc",
+      "rtpsenderreceiver_unittest.cc",
+      "statscollector_unittest.cc",
+      "test/fakeaudiocapturemodule.cc",
+      "test/fakeaudiocapturemodule.h",
+      "test/fakeaudiocapturemodule_unittest.cc",
+      "test/fakeconstraints.h",
+      "test/fakedatachannelprovider.h",
+      "test/fakeperiodicvideocapturer.h",
+      "test/fakertccertificategenerator.h",
+      "test/fakevideotrackrenderer.h",
+      "test/mockpeerconnectionobservers.h",
+      "test/peerconnectiontestwrapper.cc",
+      "test/peerconnectiontestwrapper.h",
+      "test/testsdpstrings.h",
+      "videocapturertracksource_unittest.cc",
+      "videotrack_unittest.cc",
+      "webrtcsdp_unittest.cc",
+      "webrtcsession_unittest.cc",
+    ]
+
+    defines = [ "HAVE_SCTP" ]
+
+    configs += [
+      "..:common_config",
+      ":peerconnection_unittests_config",
+    ]
+    public_configs = [ "..:common_inherited_config" ]
+
+    if (is_clang) {
+      # Suppress warnings from the Chromium Clang plugin (bugs.webrtc.org/163).
+      configs -= [ "//build/config/clang:find_bad_constructs" ]
+    }
+
+    # TODO(jschuh): Bug 1348: fix this warning.
+    configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
+
+    if (is_win) {
+      cflags = [
+        "/wd4245",  # conversion from int to size_t, signed/unsigned mismatch.
+        "/wd4389",  # signed/unsigned mismatch.
+      ]
+    }
+
+    if (rtc_use_quic) {
+      public_deps = [
+        "//third_party/libquic",
+      ]
+      sources += [
+        "quicdatachannel_unittest.cc",
+        "quicdatatransport_unittest.cc",
+      ]
+    }
+
+    deps = []
+    if (is_android) {
+      sources += [
+        "test/androidtestinitializer.cc",
+        "test/androidtestinitializer.h",
+      ]
+      deps += [
+        ":libjingle_peerconnection_jni",
+        "//testing/android/native_test:native_test_support",
+      ]
+    }
+
+    deps += [
+      ":libjingle_peerconnection",
+      "..:webrtc_common",
+      "../base:rtc_base_tests_utils",
+      "../media:rtc_unittest_main",
+      "../pc:rtc_pc",
+      "../system_wrappers:metrics_default",
+      "//testing/gmock",
+    ]
+
+    if (is_android) {
+      deps += [ "//testing/android/native_test:native_test_support" ]
+    }
+  }
+}