Pass around the candidate removals events in IOS clients

webrtc/sdk/objc/Framework/Classes/RTCPeerConnection.mm

 /*
  *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
  *
  *  Use of this source code is governed by a BSD-style license
  *  that can be found in the LICENSE file in the root of the source
  *  tree. An additional intellectual property rights grant can be found
  *  in the file PATENTS.  All contributing project authors may
  *  be found in the AUTHORS file in the root of the source tree.
  */
 
 #import "RTCPeerConnection+Private.h"
 
 #import "NSString+StdString.h"
 #import "RTCConfiguration+Private.h"
 #import "RTCDataChannel+Private.h"
 #import "RTCIceCandidate+Private.h"
 #import "RTCMediaConstraints+Private.h"
 #import "RTCMediaStream+Private.h"
 #import "RTCPeerConnectionFactory+Private.h"
 #import "RTCRtpSender+Private.h"
 #import "RTCSessionDescription+Private.h"
 #import "RTCStatsReport+Private.h"
 #import "WebRTC/RTCLogging.h"
 
 #include <memory>
 
+#include "webrtc/api/jsepicecandidate.h"
 #include "webrtc/base/checks.h"
 
 NSString * const kRTCPeerConnectionErrorDomain =
     @"org.webrtc.RTCPeerConnection";
 int const kRTCPeerConnnectionSessionDescriptionError = -1;
 
 namespace webrtc {
 
 class CreateSessionDescriptionObserverAdapter
     : public CreateSessionDescriptionObserver {
@@ skipping 137 matching lines @@
 }
 
 void PeerConnectionDelegateAdapter::OnIceCandidate(
     const IceCandidateInterface *candidate) {
   RTCIceCandidate *iceCandidate =
       [[RTCIceCandidate alloc] initWithNativeCandidate:candidate];
   RTCPeerConnection *peer_connection = peer_connection_;
   [peer_connection.delegate peerConnection:peer_connection
                    didGenerateIceCandidate:iceCandidate];
 }
+
+void PeerConnectionDelegateAdapter::OnIceCandidatesRemoved(
+    const std::vector<cricket::Candidate>& candidates) {
+  NSMutableArray* iceCandidates =

[tkchin_webrtc, 2016/05/16 20:48:58]

style in this file needs to be updated. Rule is C++ rules in C++ functions, and
ObjC rules in ObjC methods. Just update new methods for now.

So here in addition to * next to type, we also want underscores instead of camel
casing.
ice_candidates

[honghaiz3, 2016/05/17 00:46:53]

Done. also replaced iceCandidate below. 

+      [NSMutableArray arrayWithCapacity:candidates.size()];
+  for (const auto& candidate : candidates) {
+    std::unique_ptr<JsepIceCandidate> candidate_wrapper(

[tkchin_webrtc, 2016/05/16 20:48:58]

ooc, why does new api return cricket::Candidate instead of JsepIceCandidate?

[honghaiz3, 2016/05/17 00:46:53]

Good observation. We were doing that because we want to get rid of
JsepIceCandidate and just use cricket::Candidate.
We have only done that for the new code yet. 

+        new JsepIceCandidate(candidate.transport_name(), -1, candidate));
+    RTCIceCandidate* iceCandidate = [[RTCIceCandidate alloc]
+        initWithNativeCandidate:candidate_wrapper.get()];
+    [iceCandidates addObject:iceCandidate];
+  }
+  RTCPeerConnection* peer_connection = peer_connection_;
+  [peer_connection.delegate peerConnection:peer_connection
+                    didRemoveIceCandidates:iceCandidates];
+}
+
 }  // namespace webrtc
 
 
 @implementation RTCPeerConnection {
   NSMutableArray *_localStreams;
   std::unique_ptr<webrtc::PeerConnectionDelegateAdapter> _observer;
   rtc::scoped_refptr<webrtc::PeerConnectionInterface> _peerConnection;
 }
 
 @synthesize delegate = _delegate;
@@ skipping 63 matching lines @@
 - (void)close {
   _peerConnection->Close();
 }
 
 - (void)addIceCandidate:(RTCIceCandidate *)candidate {
   std::unique_ptr<const webrtc::IceCandidateInterface> iceCandidate(
       candidate.nativeCandidate);
   _peerConnection->AddIceCandidate(iceCandidate.get());
 }
 
+- (void)removeRemoteIceCandidates:(NSArray<RTCIceCandidate *> *)iceCandidates {
+  std::vector<cricket::Candidate> candidates;
+  RTCLogInfo(@"Remove %lu remote ice candidates",

[tkchin_webrtc, 2016/05/17 02:01:43]

I don't think we should log this here. It should happen in C++ land, or in the
code calling this.

[honghaiz3, 2016/05/17 06:11:23]

Done.

+             (unsigned long)[iceCandidates count]);

[tkchin_webrtc, 2016/05/16 20:48:58]

.count

[honghaiz3, 2016/05/17 00:46:53]

Done.

+  for (RTCIceCandidate *iceCandidate in iceCandidates) {
+    std::unique_ptr<const webrtc::IceCandidateInterface> candidate(
+        iceCandidate.nativeCandidate);
+    candidates.push_back(candidate->candidate());

[tkchin_webrtc, 2016/05/16 20:48:58]

probably add a if (candidate) check since nativeCandidate may be nullptr

[honghaiz3, 2016/05/17 00:46:53]

Done. Thanks!

+    // Need to fill the transport name from the sdp_mid.
+    candidates.back().set_transport_name(candidate->sdp_mid());
+  }
+  _peerConnection->RemoveIceCandidates(candidates);

[tkchin_webrtc, 2016/05/16 20:48:58]

ObjC name should match W3C name. Since this doesn't look to be in spec yet,
let's match C++ name.

removeIceCandidates

[honghaiz3, 2016/05/17 00:46:53]

C++ name style is capitalizing all words. RemoveIceCandidates. 
And this matches the rest of methods there. 

[tkchin_webrtc, 2016/05/17 02:01:43]

I was referring to the name of the method.
s/removeRemoteIceCandidates/removeIceCandidates/g

[honghaiz3, 2016/05/17 06:11:23]

Ah. I got it. You meant the method name in this class, not the line here. 
Done.

+}
+
 - (void)addStream:(RTCMediaStream *)stream {
   if (!_peerConnection->AddStream(stream.nativeMediaStream)) {
     RTCLogError(@"Failed to add stream: %@", stream);
     return;
   }
   [_localStreams addObject:stream];
 }
 
 - (void)removeStream:(RTCMediaStream *)stream {
   _peerConnection->RemoveStream(stream.nativeMediaStream);
@@ skipping 222 matching lines @@
     case RTCStatsOutputLevelDebug:
       return webrtc::PeerConnectionInterface::kStatsOutputLevelDebug;
   }
 }
 
 - (rtc::scoped_refptr<webrtc::PeerConnectionInterface>)nativePeerConnection {
   return _peerConnection;
 }
 
 @end