Add config continualGatheringPolicy to the IOS RTCConfiguration.

webrtc/sdk/objc/Framework/Classes/RTCConfiguration.mm

 /*
  *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
  *
  *  Use of this source code is governed by a BSD-style license
  *  that can be found in the LICENSE file in the root of the source
  *  tree. An additional intellectual property rights grant can be found
  *  in the file PATENTS.  All contributing project authors may
  *  be found in the AUTHORS file in the root of the source tree.
  */
 
 #import "RTCConfiguration+Private.h"
 
 #include <memory>
 
 #import "RTCIceServer+Private.h"
 #import "WebRTC/RTCLogging.h"
 
 #include "webrtc/base/sslidentity.h"
 
 @implementation RTCConfiguration
 
 @synthesize iceServers = _iceServers;
 @synthesize iceTransportPolicy = _iceTransportPolicy;
 @synthesize bundlePolicy = _bundlePolicy;
 @synthesize rtcpMuxPolicy = _rtcpMuxPolicy;
 @synthesize tcpCandidatePolicy = _tcpCandidatePolicy;
+@synthesize continualGatheringPolicy = _continualGatheringPolicy;
 @synthesize audioJitterBufferMaxPackets = _audioJitterBufferMaxPackets;
 @synthesize iceConnectionReceivingTimeout = _iceConnectionReceivingTimeout;
 @synthesize iceBackupCandidatePairPingInterval =
     _iceBackupCandidatePairPingInterval;
 @synthesize keyType = _keyType;
 
 - (instancetype)init {
   if (self = [super init]) {
     _iceServers = [NSMutableArray array];
     // Copy defaults.
     webrtc::PeerConnectionInterface::RTCConfiguration config;
     _iceTransportPolicy =
         [[self class] transportPolicyForTransportsType:config.type];
     _bundlePolicy =
         [[self class] bundlePolicyForNativePolicy:config.bundle_policy];
     _rtcpMuxPolicy =
         [[self class] rtcpMuxPolicyForNativePolicy:config.rtcp_mux_policy];
     _tcpCandidatePolicy = [[self class] tcpCandidatePolicyForNativePolicy:
         config.tcp_candidate_policy];
+    _continualGatheringPolicy =

[tkchin_webrtc, 2016/05/10 23:00:35]

nit: if it doesn't fit, put it in to a local var first instead of doing odd
indentation

[honghaiz3, 2016/05/10 23:26:08]

Done.

+        [[self class] continualGatheringPolicyForNativePolicy:
+                          config.continual_gathering_policy];
     _audioJitterBufferMaxPackets = config.audio_jitter_buffer_max_packets;
     _iceConnectionReceivingTimeout = config.ice_connection_receiving_timeout;
     _iceBackupCandidatePairPingInterval =
         config.ice_backup_candidate_pair_ping_interval;
     _keyType = RTCEncryptionKeyTypeECDSA;
   }
   return self;
 }
 
 - (NSString *)description {
   return [NSString stringWithFormat:
-      @"RTCConfiguration: {\n%@\n%@\n%@\n%@\n%@\n%d\n%d\n%d\n}\n",
+      @"RTCConfiguration: {\n%@\n%@\n%@\n%@\n%@\n%@\n%d\n%d\n%d\n}\n",
       _iceServers,
       [[self class] stringForTransportPolicy:_iceTransportPolicy],
       [[self class] stringForBundlePolicy:_bundlePolicy],
       [[self class] stringForRtcpMuxPolicy:_rtcpMuxPolicy],
       [[self class] stringForTcpCandidatePolicy:_tcpCandidatePolicy],
+      [[self class]
+          stringForContinualGatheringPolicy:_continualGatheringPolicy],
       _audioJitterBufferMaxPackets,
       _iceConnectionReceivingTimeout,
       _iceBackupCandidatePairPingInterval];
 }
 
 #pragma mark - Private
 
 - (webrtc::PeerConnectionInterface::RTCConfiguration)nativeConfiguration {
   webrtc::PeerConnectionInterface::RTCConfiguration nativeConfig;
 
   for (RTCIceServer *iceServer in _iceServers) {
     nativeConfig.servers.push_back(iceServer.nativeServer);
   }
   nativeConfig.type =
       [[self class] nativeTransportsTypeForTransportPolicy:_iceTransportPolicy];
   nativeConfig.bundle_policy =
       [[self class] nativeBundlePolicyForPolicy:_bundlePolicy];
   nativeConfig.rtcp_mux_policy =
       [[self class] nativeRtcpMuxPolicyForPolicy:_rtcpMuxPolicy];
   nativeConfig.tcp_candidate_policy =
       [[self class] nativeTcpCandidatePolicyForPolicy:_tcpCandidatePolicy];
+  nativeConfig.continual_gathering_policy = [[self class]
+      nativeContinualGatheringPolicyForPolicy:_continualGatheringPolicy];
   nativeConfig.audio_jitter_buffer_max_packets = _audioJitterBufferMaxPackets;
   nativeConfig.ice_connection_receiving_timeout =
       _iceConnectionReceivingTimeout;
   nativeConfig.ice_backup_candidate_pair_ping_interval =
       _iceBackupCandidatePairPingInterval;
   if (_keyType == RTCEncryptionKeyTypeECDSA) {
     std::unique_ptr<rtc::SSLIdentity> identity(
         rtc::SSLIdentity::Generate(webrtc::kIdentityName, rtc::KT_ECDSA));
     if (identity) {
       nativeConfig.certificates.push_back(
@@ skipping 133 matching lines @@
 
 + (NSString *)stringForTcpCandidatePolicy:(RTCTcpCandidatePolicy)policy {
   switch (policy) {
     case RTCTcpCandidatePolicyEnabled:
       return @"TCP_ENABLED";
     case RTCTcpCandidatePolicyDisabled:
       return @"TCP_DISABLED";
   }
 }
 
++ (webrtc::PeerConnectionInterface::ContinualGatheringPolicy)
+    nativeContinualGatheringPolicyForPolicy:
+        (RTCContinualGatheringPolicy)policy {
+  switch (policy) {
+    case RTCGatherOnce:
+      return webrtc::PeerConnectionInterface::GATHER_ONCE;
+    case RTCGatherContinually:
+      return webrtc::PeerConnectionInterface::GATHER_CONTINUALLY;
+  }
+}
+
++ (RTCContinualGatheringPolicy) continualGatheringPolicyForNativePolicy:

[tkchin_webrtc, 2016/05/10 23:00:35]

nit: remove space

[honghaiz3, 2016/05/10 23:26:08]

Done.

+    (webrtc::PeerConnectionInterface::ContinualGatheringPolicy)nativePolicy {
+  switch (nativePolicy) {
+    case webrtc::PeerConnectionInterface::GATHER_ONCE:
+      return RTCGatherOnce;
+    case webrtc::PeerConnectionInterface::GATHER_CONTINUALLY:
+      return RTCGatherContinually;
+  }
+}
+
++ (NSString *) stringForContinualGatheringPolicy:

[tkchin_webrtc, 2016/05/10 23:00:34]

nit: remove space

[honghaiz3, 2016/05/10 23:26:08]

Done.

+    (RTCContinualGatheringPolicy)policy {
+  switch (policy) {
+    case RTCGatherOnce:
+      return @"GATHER_ONCE";
+    case RTCGatherContinually:
+      return @"GATHER_CONTINUALLY";
+  }
+}
+
 @end