Update API for Objective-C RTCPeerConnection.

webrtc/api/objc/RTCPeerConnection+Stats.mm

Index: webrtc/api/objc/RTCPeerConnection+Stats.mm
diff --git a/webrtc/api/objc/RTCPeerConnection+Stats.mm b/webrtc/api/objc/RTCPeerConnection+Stats.mm
new file mode 100644
index 0000000000000000000000000000000000000000..714ccde14e789a9ea76fb85e08b5b73fe326244e
--- /dev/null
+++ b/webrtc/api/objc/RTCPeerConnection+Stats.mm
@@ -0,0 +1,62 @@
+/*
+ *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import "RTCPeerConnection+Private.h"
+
+#import "webrtc/api/objc/RTCMediaStreamTrack+Private.h"
+#import "webrtc/api/objc/RTCStatsReport+Private.h"
+#import "webrtc/base/objc/NSString+StdString.h"
+
+namespace webrtc {
+class StatsObserverAdapter : public StatsObserver {
+ public:
+  StatsObserverAdapter(void (^completionHandler)
+      (NSArray<RTCStatsReport *> *stats)) {
+    completion_handler_ = completionHandler;
+  }
+
+  ~StatsObserverAdapter() {
+    completion_handler_ = nil;
+  }
+
+  void OnComplete(const StatsReports& reports) override {
+    NSMutableArray *stats = [NSMutableArray arrayWithCapacity:reports.size()];
+    for (const auto* report : reports) {
+      RTCStatsReport *statsReport =
+          [[RTCStatsReport alloc] initWithNativeReport:*report];
+      [stats addObject:statsReport];
+    }
+    if (completion_handler_) {

[tkchin_webrtc, 2016/02/10 18:54:40]

in the same spirit as prior comments, assert/call/set-to-nil

[hjon_webrtc, 2016/02/11 00:25:08]

Done.

+      completion_handler_(stats);
+    }
+    Block_release(completion_handler_);

[tkchin_webrtc, 2016/02/10 18:54:40]

Don't call Block_release, just set to nil

[hjon_webrtc, 2016/02/11 00:25:08]

Done.

+  }
+
+ private:
+  void (^completion_handler_)(NSArray *stats);
+};
+}  // namespace webrtc
+
+@implementation RTCPeerConnection (Stats)
+
+- (void)statsForMediaStreamTrack:(RTCMediaStreamTrack *)mediaStreamTrack
+                statsOutputLevel:(RTCStatsOutputLevel)statsOutputLevel
+               completionHandler:
+    (void (^)(NSArray<RTCStatsReport *> *stats))completionHandler {
+  rtc::scoped_refptr<webrtc::StatsObserverAdapter> observer(
+      new rtc::RefCountedObject<webrtc::StatsObserverAdapter>
+          (completionHandler));
+  webrtc::PeerConnectionInterface::StatsOutputLevel nativeOutputLevel =
+      [[self class] nativeStatsOutputLevelForLevel:statsOutputLevel];
+  self.nativePeerConnection->GetStats(
+      observer, mediaStreamTrack.nativeTrack, nativeOutputLevel);
+}
+
+@end