Update API for Objective-C RTCMediaStream.

webrtc/api/objc/RTCMediaStream.mm

Index: webrtc/api/objc/RTCMediaStream.mm
diff --git a/webrtc/api/objc/RTCMediaStream.mm b/webrtc/api/objc/RTCMediaStream.mm
new file mode 100644
index 0000000000000000000000000000000000000000..336b1db5032a7fd550b866d67c8c248eab69ef88
--- /dev/null
+++ b/webrtc/api/objc/RTCMediaStream.mm
@@ -0,0 +1,112 @@
+/*
+ *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import "RTCMediaStream.h"
+
+#include <vector>
+
+#import "webrtc/api/objc/RTCAudioTrack+Private.h"
+#import "webrtc/api/objc/RTCMediaStream+Private.h"
+#import "webrtc/api/objc/RTCMediaStreamTrack+Private.h"
+#import "webrtc/api/objc/RTCVideoTrack+Private.h"
+#import "webrtc/base/objc/NSString+StdString.h"
+
+@implementation RTCMediaStream {
+  NSMutableArray* _audioTracks;

[tkchin_webrtc, 2016/01/21 23:51:53]

space *
rest of file too

[hjon, 2016/01/21 23:56:22]

Done.

+  NSMutableArray* _videoTracks;
+  rtc::scoped_refptr<webrtc::MediaStreamInterface> _mediaStream;

[tkchin_webrtc, 2016/01/21 23:51:53]

_nativeMediaStream

[hjon, 2016/01/21 23:56:22]

Done.

+}
+
+- (NSArray<RTCAudioTrack *> *)audioTracks {
+  return [_audioTracks copy];
+}
+
+- (NSArray<RTCVideoTrack *> *)videoTracks {
+  return [_videoTracks copy];
+}
+
+- (NSString *)streamId {
+  return [NSString stringForStdString:_mediaStream->label()];
+}
+
+- (void)addAudioTrack:(RTCAudioTrack *)audioTrack {
+  if (_mediaStream->AddTrack(audioTrack.nativeAudioTrack)) {
+    [_audioTracks addObject:audioTrack];
+  }
+}
+
+- (void)addVideoTrack:(RTCVideoTrack *)videoTrack {
+  if (_mediaStream->AddTrack(videoTrack.nativeVideoTrack)) {
+    [_videoTracks addObject:videoTrack];
+  }
+}
+
+- (void)removeAudioTrack:(RTCAudioTrack *)audioTrack {
+  NSUInteger index = [_audioTracks indexOfObjectIdenticalTo:audioTrack];
+  NSAssert(index != NSNotFound,
+           @"|removeAudioTrack| called on unexpected RTCAudioTrack");
+  if (index != NSNotFound &&
+      _mediaStream->RemoveTrack(audioTrack.nativeAudioTrack)) {
+    [_audioTracks removeObjectAtIndex:index];
+  }
+}
+
+- (void)removeVideoTrack:(RTCVideoTrack *)videoTrack {
+  NSUInteger index = [_videoTracks indexOfObjectIdenticalTo:videoTrack];
+  NSAssert(index != NSNotFound,
+           @"|removeVideoTrack| called on unexpected RTCVideoTrack");
+  if (index != NSNotFound &&
+      _mediaStream->RemoveTrack(videoTrack.nativeVideoTrack)) {
+    [_videoTracks removeObjectAtIndex:index];
+  }
+}
+
+- (NSString *)description {
+  return [NSString stringWithFormat:@"RTCMediaStream:\n%@\nA=%lu\nV=%lu",
+                                    self.streamId,
+                                    (unsigned long)self.audioTracks.count,
+                                    (unsigned long)self.videoTracks.count];
+}
+
+#pragma mark - Private
+
+- (rtc::scoped_refptr<webrtc::MediaStreamInterface>)nativeMediaStream {
+  return _mediaStream;
+}
+
+- (instancetype)initWithNativeStream:
+    (rtc::scoped_refptr<webrtc::MediaStreamInterface>)nativeMediaStream {
+  NSParameterAssert(nativeMediaStream);
+  if (self = [super init]) {
+    webrtc::AudioTrackVector audioTracks = nativeMediaStream->GetAudioTracks();
+    webrtc::VideoTrackVector videoTracks = nativeMediaStream->GetVideoTracks();
+
+    _audioTracks = [NSMutableArray arrayWithCapacity:audioTracks.size()];
+    _videoTracks = [NSMutableArray arrayWithCapacity:videoTracks.size()];
+    _mediaStream = nativeMediaStream;
+
+    for ( auto &track : audioTracks ) {

[tkchin_webrtc, 2016/01/21 23:51:53]

remove spaces
(auto ... tracks) {

[hjon, 2016/01/21 23:56:22]

Done.

+      RTCAudioTrack *audioTrack =
+          [[RTCAudioTrack alloc] initWithNativeMediaTrack:track
+              type:RTCMediaStreamTrackTypeAudio];

[tkchin_webrtc, 2016/01/21 23:51:53]

align :

[hjon, 2016/01/21 23:56:22]

Done.

+      [_audioTracks addObject:audioTrack];
+    }
+
+    for ( auto &track : videoTracks ) {

[tkchin_webrtc, 2016/01/21 23:51:53]

ditto

[hjon, 2016/01/21 23:56:22]

Done.

+      RTCVideoTrack *videoTrack =
+          [[RTCVideoTrack alloc] initWithNativeMediaTrack:track
+              type:RTCMediaStreamTrackTypeVideo];
+      [_videoTracks addObject:videoTrack];
+    }
+  }
+  return self;
+}
+
+@end