Update/move RTCVideoRendererAdapter to webrtc/api/objc.

webrtc/api/objc/RTCVideoRendererAdapter.mm

+/*
+ *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import "RTCVideoRendererAdapter.h"
+#import "RTCI420Frame+Private.h"
+
+namespace webrtc {
+
+class RTCVideoRendererNativeAdapter : public VideoRendererInterface {
+ public:
+  RTCVideoRendererNativeAdapter(RTCVideoRendererAdapter *adapter) {
+    _adapter = adapter;
+    _size = CGSizeZero;
+  }
+
+  void RenderFrame(const cricket::VideoFrame *videoFrame) override {
+    const cricket::VideoFrame *frame = videoFrame->GetCopyWithRotationApplied();
+    CGSize currentSize = CGSizeMake(frame->GetWidth(), frame->GetHeight());
+    if (!CGSizeEqualToSize(_size, currentSize)) {
+      _size = currentSize;
+      [_adapter.videoRenderer setSize:_size];

[tkchin_webrtc, 2016/01/05 21:59:02]

Do we need setSize? If C++ impl junked it maybe we should too. What does Android
do?

[hjon, 2016/01/08 01:00:52]

Looks like the only thing setSize does in the renderer's implementation is
notify delegates that the size changed. From what I can see in digging around in
Android a bit, there appears to be a similar kind of notification about the size
changing. It seems that it may be useful to provide this information about the
size changing for layout purposes. What do you think about putting this logic in
the renderer instead?

+    }
+    RTCI420Frame *i420Frame = [[RTCI420Frame alloc] initWithVideoFrame:frame];
+    [_adapter.videoRenderer renderFrame:i420Frame];
+  }
+
+ private:
+  __weak RTCVideoRendererAdapter *_adapter;
+  CGSize _size;
+};
+}
+
+@implementation RTCVideoRendererAdapter {
+  rtc::scoped_ptr<webrtc::RTCVideoRendererNativeAdapter> _adapter;
+}
+
+@synthesize videoRenderer = _videoRenderer;
+
+- (instancetype)initWithVideoRenderer:(id<RTCVideoRenderer>)videoRenderer {
+  NSParameterAssert(videoRenderer);
+  if (self = [super init]) {
+    _videoRenderer = videoRenderer;
+    _adapter.reset(new webrtc::RTCVideoRendererNativeAdapter(self));
+  }
+  return self;
+}
+
+- (webrtc::VideoRendererInterface *)nativeVideoRenderer {
+  return _adapter.get();
+}
+
+@end