Update API for Objective-C RTCMediaStreamTrack

webrtc/api/objc/RTCMediaStreamTrack.mm

+/*
+ *  Copyright 2015 The WebRTC project authors. All Rights Reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#import "RTCMediaStreamTrack.h"
+
+#import "webrtc/api/objc/RTCMediaStreamTrack+Private.h"
+#import "webrtc/base/objc/NSString+StdString.h"
+
+@interface RTCMediaStreamTrack () {
+  rtc::scoped_refptr<webrtc::MediaStreamTrackInterface> _track;
+}
+@end
+
+@implementation RTCMediaStreamTrack
+
+- (NSString *)kind {
+  return [NSString stringForStdString:_track->kind()];
+}
+
+- (NSString *)trackId {
+  return [NSString stringForStdString:_track->id()];
+}
+
+- (BOOL)isEnabled {
+  return _track->enabled();
+}
+
+- (void)setIsEnabled:(BOOL)enabled {

[tkchin_webrtc, 2016/01/06 19:30:52]

isEnabled

+  _track->set_enabled(enabled);
+}
+
+- (RTCMediaStreamTrackState)readyState {
+  return [[self class] trackStateForNativeState:_track->state()];
+}
+
+- (NSString *)description {
+  return [NSString stringWithFormat:@"RTCMediaStreamTrack:\n%@\n%@\n%@\n%@",
+                                    self.kind,
+                                    self.trackId,
+                                    self.isEnabled ? @"enabled" : @"disabled",
+                                    [[self class] stringForState:
+                                        self.readyState]];

[tkchin_webrtc, 2016/01/06 19:30:52]

move into a local first to avoid the weird indentation

+}
+
+#pragma mark - Private
+
+- (rtc::scoped_refptr<webrtc::MediaStreamTrackInterface>)nativeTrack {
+  return _track;
+}
+
+- (instancetype)initWithNativeTrack:
+    (rtc::scoped_refptr<webrtc::MediaStreamTrackInterface>)track {
+  NSParameterAssert(track);
+  if (self = [super init]) {
+    _track =  track;
+  }
+  return self;
+}
+
++ (webrtc::MediaStreamTrackInterface::TrackState)nativeTrackStateForState:
+    (RTCMediaStreamTrackState)state {
+  switch (state) {
+    case RTCMediaStreamTrackStateInitializing:
+      return webrtc::MediaStreamTrackInterface::kInitializing;
+    case RTCMediaStreamTrackStateLive:
+      return webrtc::MediaStreamTrackInterface::kLive;
+    case RTCMediaStreamTrackStateEnded:
+      return webrtc::MediaStreamTrackInterface::kEnded;
+    case RTCMediaStreamTrackStateFailed:
+      return webrtc::MediaStreamTrackInterface::kFailed;
+  }
+}
+
++ (RTCMediaStreamTrackState)trackStateForNativeState:
+    (webrtc::MediaStreamTrackInterface::TrackState)nativeState {
+  switch (nativeState) {
+    case webrtc::MediaStreamTrackInterface::kInitializing:
+      return RTCMediaStreamTrackStateInitializing;
+    case webrtc::MediaStreamTrackInterface::kLive:
+      return RTCMediaStreamTrackStateLive;
+    case webrtc::MediaStreamTrackInterface::kEnded:
+      return RTCMediaStreamTrackStateEnded;
+    case webrtc::MediaStreamTrackInterface::kFailed:
+      return RTCMediaStreamTrackStateFailed;
+  }
+}
+
++ (NSString *)stringForState:

[tkchin_webrtc, 2016/01/06 19:30:52]

I think it fits on one line

+    (RTCMediaStreamTrackState)state {
+  switch (state) {
+    case RTCMediaStreamTrackStateInitializing:
+      return @"Initializing";
+    case RTCMediaStreamTrackStateLive:
+      return @"Live";
+    case RTCMediaStreamTrackStateEnded:
+      return @"Ended";
+    case RTCMediaStreamTrackStateFailed:
+      return @"Failed";
+  }
+}
+
+@end