Adds support for webrtc::test::ResourcePath on iOS

webrtc/test/testsupport/iosfileutils.mm

+/*
+ *  Copyright 2014 The WebRTC Project Authors. All rights reserved.
+ *
+ *  Use of this source code is governed by a BSD-style license
+ *  that can be found in the LICENSE file in the root of the source
+ *  tree. An additional intellectual property rights grant can be found
+ *  in the file PATENTS.  All contributing project authors may
+ *  be found in the AUTHORS file in the root of the source tree.
+ */
+
+#if defined(WEBRTC_IOS)
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+#import <Foundation/Foundation.h>
+#include <string.h>
+
+#include "webrtc/base/checks.h"
+#include "webrtc/typedefs.h"
+
+NSString* NSStringFromStdString(const std::string& stdString) {

[tkchin_webrtc, 2015/06/12 17:43:35]

We haven't been consistent with placement of * in mixed ObjC/C++ code. Usually
if just ObjC we want NSString *NSStringFromStdString (widely adopted style). I'm
okay with what you have for mixed code though.

Can you file bug / add TODO for placing these general functions in a shared
location?

[henrika_webrtc, 2015/06/15 08:46:29]

Filed https://code.google.com/p/webrtc/issues/detail?id=4773 and added TODO.
Please add comments if my summary is not inline with what you intended.

PS; what do you mean by "with placement of * in mixed ObjC/C++ code" in this
context?

[tkchin_webrtc, 2015/06/15 20:23:13]

Here we're defining static functions, but making use of ObjC classes. In C++,
the style is to place * next to type. eg. char* c; In ObjC the style is to place
* away from type, e.g. NSString *path; In mixed code, where std::string lives
together with NSString, it becomes a little bit murky, and I think it is
acceptable to use NSString* path in this case.

+  // std::string may contain null termination character so we construct
+  // using length.
+  return [[NSString alloc] initWithBytes:stdString.data()
+                                  length:stdString.length()
+                                encoding:NSUTF8StringEncoding];
+}
+
+std::string StdStringFromNSString(NSString* nsString) {
+  NSData* charData = [nsString dataUsingEncoding:NSUTF8StringEncoding];
+  return std::string(reinterpret_cast<const char*>([charData bytes]),
+                     [charData length]);
+}
+
+// For iOS, resource files are added to the application bundle in the root
+// and not in separate folders as is the case for other platforms. This method
+// therefore removes any prepended folders and uses only the actual file name.
+std::string IOSResourcePath(std::string name, std::string extension) {
+  std::string file_name = name;

[tkchin_webrtc, 2015/06/12 17:43:35]

I think it is better to avoid mixing if all all possible. The ObjC way to do
this is:
NSString *path = NSStringFromStdString(name);
NSString *fileName = path.lastPathComponent;

[henrika_webrtc, 2015/06/15 08:46:29]

Great stuff. I am no Objective-C guru...yet ;-)

+  std::size_t pos = name.find_last_of("/");
+  if (pos != std::string::npos) {
+    // Extract name of file and exclude the added path.
+    // Example: name: "audio_coding/testfile32kHz" => file_name: "testfile32kHz"
+    file_name = name.substr(pos + 1);
+  }
+  @autoreleasepool {
+    NSString* nameString = NSStringFromStdString(file_name);
+    NSString* typeString = NSStringFromStdString(extension);
+    // Get full pathname for the resource identified by the name and extension.
+    NSString* pathString = [[NSBundle mainBundle] pathForResource: nameString

[tkchin_webrtc, 2015/06/12 17:43:35]

remove spaces after :

[henrika_webrtc, 2015/06/15 08:46:29]

Done.

+                                                           ofType: typeString];
+    return StdStringFromNSString(pathString);
+  }
+}
+
+#endif  // defined(WEBRTC_IOS)